reserve p, q for FinSequence,
  X, Y, x, y, e for set,
  D for non empty set,
  i, j, k, l, m, n, r for Nat;
reserve G for Graph;
reserve v, v1, v2, v3, v4 for Element of G;
reserve vs, vs1, vs2 for FinSequence of the carrier of G,
  c, c1, c2 for Chain of G;
reserve sc for simple Chain of G;

theorem
  vs is_vertex_seq_of c implies ex fc being Subset of c, fvs being
Subset of vs, sc, vs1 st Seq fc = sc & Seq fvs = vs1 & vs1 is_vertex_seq_of sc
  & vs.1 = vs1.1 & vs.len vs = vs1.len vs1
proof
  assume
A1: vs is_vertex_seq_of c;
  per cases;
  suppose
    c is simple Chain of G;
    then reconsider sc = c as simple Chain of G;
    reconsider fvs = vs as Subset of vs by FINSEQ_6:152;
    reconsider fc = c as Subset of c by FINSEQ_6:152;
    take fc, fvs, sc, vs;
    thus Seq fc = sc & Seq fvs = vs by FINSEQ_3:116;
    thus vs is_vertex_seq_of sc by A1;
    thus thesis;
  end;
  suppose
A2: not c is simple Chain of G;
    defpred P[Nat] means ex fc being Subset of c, fvs being Subset of vs, c1,
vs1 st Seq fc = c1 & Seq fvs = vs1 & vs1 is_vertex_seq_of c1 & vs.1 = vs1.1 &
    vs.len vs = vs1.len vs1 & len c1 = $1 & not c1 is simple Chain of G;
    P[len c qua Element of NAT]
    proof
      reconsider fvs = vs as Subset of vs by FINSEQ_6:152;
      reconsider fc = c as Subset of c by FINSEQ_6:152;
      take fc, fvs, c,vs;
      thus Seq fc = c & Seq fvs = vs by FINSEQ_3:116;
      thus vs is_vertex_seq_of c by A1;
      thus vs.1 = vs.1 & vs.len vs = vs.len vs;
      thus thesis by A2;
    end;
    then
A3: ex k be Nat st P[k];
    consider k be Nat such that
A4: P[k] & for n being Nat st P[n] holds k<=n from NAT_1:sch 5(A3);
    consider fc being Subset of c, fvs being Subset of vs, c1, vs1 such that
A5: Seq fc = c1 and
A6: Seq fvs = vs1 and
A7: vs1 is_vertex_seq_of c1 and
A8: vs.1 = vs1.1 and
A9: vs.len vs = vs1.len vs1 and
A10: len c1 = k and
A11: not c1 is simple Chain of G by A4;
    consider fc1 being Subset of c1, fvs1 being Subset of vs1, c2, vs2 such
    that
A12: len c2 < len c1 and
A13: vs2 is_vertex_seq_of c2 and
    len vs2 < len vs1 and
A14: vs1.1 = vs2.1 and
A15: vs1.len vs1 = vs2.len vs2 and
A16: Seq fc1 = c2 and
A17: Seq fvs1 = vs2 by A7,A11,Th48;
    reconsider fc9=fc|rng((Sgm dom fc)|dom fc1) as Subset of c
      by FINSEQ_6:153;
    reconsider fvs9=fvs|rng((Sgm dom fvs)|dom fvs1) as Subset of vs
      by FINSEQ_6:153;
A18: Seq fvs9 = vs2 by A6,A17,FINSEQ_6:154;
A19: Seq fc9 = c2 by A5,A16,FINSEQ_6:154;
    then c2 is simple Chain of G implies thesis by A8,A9,A13,A14,A15,A18;
    hence thesis by A4,A8,A9,A10,A12,A13,A14,A15,A19,A18;
  end;
end;
