
theorem Th49:
for f be PartFunc of REAL,REAL, r be Real st dom f = REAL &
 f is_improper_integrable_on_REAL holds
  r(#)f is_improper_integrable_on_REAL &
  improper_integral_on_REAL (r(#)f) = r * improper_integral_on_REAL(f)
proof
    let f be PartFunc of REAL,REAL, r be Real;
    assume that
A1:  dom f = REAL and
A2:  f is_improper_integrable_on_REAL;

    consider c be Real such that
     f is_-infty_improper_integrable_on c and
     f is_+infty_improper_integrable_on c and
A3:  not (improper_integral_-infty(f,c) = -infty
        & improper_integral_+infty(f,c) = +infty) and
A4:  not (improper_integral_-infty(f,c) = +infty
        & improper_integral_+infty(f,c) = -infty) by A2;

    f is_-infty_improper_integrable_on c
  & f is_+infty_improper_integrable_on c by A1,A2,Th36; then
A5: r(#)f is_-infty_improper_integrable_on c
  & r(#)f is_+infty_improper_integrable_on c
  & improper_integral_-infty(r(#)f,c) = r * improper_integral_-infty(f,c)
  & improper_integral_+infty(r(#)f,c) = r * improper_integral_+infty(f,c)
  by A1,Th41,Th42;

A6: improper_integral_-infty(r(#)f,c) + improper_integral_+infty(r(#)f,c)
     = r * (improper_integral_-infty(f,c) + improper_integral_+infty(f,c))
       by A5,XXREAL_3:95
    .= r * improper_integral_on_REAL f by A1,A2,Th36;

A7: dom(r(#)f) = dom f by VALUED_1:def 5;

    per cases;
    suppose r = 0;
     hence r(#)f is_improper_integrable_on_REAL by A5;
     hence improper_integral_on_REAL (r(#)f) = r * improper_integral_on_REAL f
       by A1,A6,A7,Th36;
    end;
    suppose A8: r > 0;
A9:  now assume A10: improper_integral_-infty(r(#)f,c) = -infty
       & improper_integral_+infty(r(#)f,c) = +infty; then
      improper_integral_-infty(f,c) = +infty or
      improper_integral_-infty(f,c) = -infty by A5,XXREAL_3:70;
      hence contradiction by A3,A10,A5,A8,XXREAL_3:69;
     end;

A11:  now assume A12: improper_integral_-infty(r(#)f,c) = +infty
       & improper_integral_+infty(r(#)f,c) = -infty; then
      improper_integral_-infty(f,c) = +infty or
      improper_integral_-infty(f,c) = -infty by A5,XXREAL_3:69;
      hence contradiction by A4,A12,A5,A8,XXREAL_3:70;
     end;

     thus r(#)f is_improper_integrable_on_REAL by A5,A9,A11;
     hence improper_integral_on_REAL (r(#)f)
      = r * improper_integral_on_REAL f
       by A1,A6,A7,Th36;
    end;
    suppose A13: r < 0;
A14:  now assume A15: improper_integral_-infty(r(#)f,c) = -infty
       & improper_integral_+infty(r(#)f,c) = +infty; then
      improper_integral_-infty(f,c) = +infty or
      improper_integral_-infty(f,c) = -infty by A5,XXREAL_3:70;
      hence contradiction by A4,A15,A5,A13,XXREAL_3:69;
     end;

A16:  now assume A17: improper_integral_-infty(r(#)f,c) = +infty
       & improper_integral_+infty(r(#)f,c) = -infty; then
      improper_integral_-infty(f,c) = +infty or
      improper_integral_-infty(f,c) = -infty by A5,XXREAL_3:69;
      hence contradiction by A3,A17,A5,A13,XXREAL_3:70;
     end;

     thus r(#)f is_improper_integrable_on_REAL by A5,A14,A16;
     hence improper_integral_on_REAL (r(#)f)
       = r * improper_integral_on_REAL f
       by A1,A6,A7,Th36;
    end;
end;
