reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;

theorem Th36:
  for a being Real, Q being Subset of TOP-REAL n, w1,w7 being
Point of TOP-REAL n st n>=2 & Q=(REAL n)\ {q : (|.q.|) < a } & w1 in Q & w7 in
Q &
 (ex r being Real st w1=r*w7 or w7=r*w1)
  holds ex w2,w3,w4,w5,w6 being Point
of TOP-REAL n st w2 in Q & w3 in Q & w4 in Q & w5 in Q & w6 in Q & LSeg(w1,w2)
c=Q & LSeg(w2,w3) c= Q & LSeg(w3,w4) c= Q & LSeg(w4,w5) c= Q & LSeg(w5,w6) c=Q
  & LSeg(w6,w7) c= Q
proof
  let a be Real,
      Q be Subset of TOP-REAL n, w1,w7 be Point of TOP-REAL n;
  reconsider y1=w1 as Element of REAL n by EUCLID:22;
  assume
A1: n>=2 & Q=(REAL n)\ {q : (|.q.|) < a } & w1 in Q & w7 in Q & ex r
  being Real st w1=r*w7 or w7=r*w1;
  then consider r8 being Real such that
A2: w1=r8*w7 or w7=r8*w1;
  per cases;
  suppose
A3: a>0;
    now
      assume w1=0.TOP-REAL n;
      then |.w1.|=0 by TOPRNS_1:23;
      then w1 in {q : (|.q.|) < a } by A3;
      hence contradiction by A1,XBOOLE_0:def 5;
    end;
    then w1 <> 0*n by EUCLID:70;
    then consider y being Element of REAL n such that
A4: not ex r being Real st y=r*y1 or y1=r*y by A1,Th34;
    set y4=(a/|.y.|)*y;
    reconsider w4=y4 as Point of TOP-REAL n by EUCLID:22;
A5: now
A6:   0 *y1 = 0 * w1
        .= 0.TOP-REAL n by RLVECT_1:10
        .=0*n by EUCLID:70;
      assume |.y.|=0;
      hence contradiction by A4,A6,EUCLID:8;
    end;
    then
A7: a/|.y.|>0 by A3,XREAL_1:139;
A8: now
      reconsider y9=y,y19=y1 as Element of n-tuples_on REAL;
      given r being Real such that
A9:   w1=r*w4 or w4=r*w1;
      y1=(r*(a/|.y.|))*y or (a/|.y.|)"*(a/|.y.|)*y9=(a/|.y.|)"*(r*y1)
              by A9,RVSUM_1:49;
      then y1=(r*(a/|.y.|))*y or (a/|.y.|)"*(a/|.y.|)*y=(a/|.y.|)"*r*y19 by
RVSUM_1:49;
      then
A10:  y1=(r*(a/|.y.|))*y9 or 1 *y=(a/|.y.|)"*r*y1 by A7,XCMPLX_0:def 7;
      per cases by A10,RVSUM_1:52;
      suppose
        y1=(r*(a/|.y.|))*y;
        hence contradiction by A4;
      end;
      suppose
        y=(a/|.y.|)"*r*y1;
        hence contradiction by A4;
      end;
    end;
A11: |.w4.|=|.a/|.y.|.|*|.y.| by EUCLID:11
      .= a/|.y.|*|.y.| by A3,ABSVALUE:def 1
      .=a by A5,XCMPLX_1:87;
A12: now
      assume w4 in {q : (|.q.|) < a };
      then ex q st q=w4 & (|.q.|) < a;
      hence contradiction by A11;
    end;
    then
A13: w4 in Q by A1,XBOOLE_0:def 5;
    now
      given r1 being Real such that
A14:  w4=r1*w7 or w7=r1*w4;
A15:  now
        assume r1=0;
        then w4=0.TOP-REAL n or w7=0.TOP-REAL n by A14,RLVECT_1:10;
        then |.w4.|=0 or |.w7.|=0 by TOPRNS_1:23;
        then w4 in {q : (|.q.|) < a } or w7 in {q2 where q2 is Point of
        TOP-REAL n: (|.q2.|) < a } by A3;
        hence contradiction by A1,A12,XBOOLE_0:def 5;
      end;
      now
        per cases by A2;
        case
A16:      w1=r8*w7;
          now
            per cases by A14;
            case
              w4=r1*w7;
              then r1"*w4=r1"*r1*w7 by RLVECT_1:def 7;
              then r1"*w4=1 *w7 by A15,XCMPLX_0:def 7;
              then r1"*w4=w7 by RLVECT_1:def 8;
              then w1=r8*r1"*w4 by A16,RLVECT_1:def 7;
              hence contradiction by A8;
            end;
            case
              w7=r1*w4;
              then r1"*w7=r1"*r1*w4 by RLVECT_1:def 7;
              then r1"*w7=1 *w4 by A15,XCMPLX_0:def 7;
              then r1"*w7=w4 by RLVECT_1:def 8;
              then r1""*w4=r1""*r1"*w7 by RLVECT_1:def 7;
              then r1""*w4=1 *w7 by A15,XCMPLX_0:def 7;
              then r1""*w4=w7 by RLVECT_1:def 8;
              then w1=r8*r1""*w4 by A16,RLVECT_1:def 7;
              hence contradiction by A8;
            end;
          end;
          hence contradiction;
        end;
        case
A17:      w7=r8*w1;
A18:      now
            assume r8=0;
            then w7=0.TOP-REAL n by A17,RLVECT_1:10;
            then |.w7.|=0 by TOPRNS_1:23;
            then w7 in {q : (|.q.|) < a } by A3;
            hence contradiction by A1,XBOOLE_0:def 5;
          end;
          r8"*w7=r8"*r8*w1 by A17,RLVECT_1:def 7;
          then r8"*w7=1 *w1 by A18,XCMPLX_0:def 7;
          then
A19:      r8"*w7=w1 by RLVECT_1:def 8;
          now
            per cases by A14;
            case
              w4=r1*w7;
              then r1"*w4=r1"*r1*w7 by RLVECT_1:def 7;
              then r1"*w4=1 *w7 by A15,XCMPLX_0:def 7;
              then r1"*w4=w7 by RLVECT_1:def 8;
              then w1=r8"*r1"*w4 by A19,RLVECT_1:def 7;
              hence contradiction by A8;
            end;
            case
              w7=r1*w4;
              then r1"*w7=r1"*r1*w4 by RLVECT_1:def 7;
              then r1"*w7=1 *w4 by A15,XCMPLX_0:def 7;
              then r1"*w7=w4 by RLVECT_1:def 8;
              then r1""*w4=r1""*r1"*w7 by RLVECT_1:def 7;
              then r1""*w4=1 *w7 by A15,XCMPLX_0:def 7;
              then r1""*w4=w7 by RLVECT_1:def 8;
              then w1=r8"*r1""*w4 by A19,RLVECT_1:def 7;
              hence contradiction by A8;
            end;
          end;
          hence contradiction;
        end;
      end;
      hence contradiction;
    end;
    then
A20: ex w29,w39 being Point of TOP-REAL n st w29 in Q & w39 in Q & LSeg(w4,
    w29) c=Q & LSeg(w29,w39) c= Q & LSeg(w39,w7) c= Q by A1,A13,Th30;
    ex w2,w3 being Point of TOP-REAL n st w2 in Q & w3 in Q & LSeg(w1,w2)
    c=Q & LSeg(w2,w3) c= Q & LSeg(w3,w4) c= Q by A1,A13,A8,Th30;
    hence thesis by A13,A20;
  end;
  suppose
A21: a<=0;
    set w2=0.TOP-REAL n;
A22: REAL n c= Q
    proof
      let x be object;
A23:  now
        assume x in {q : (|.q.|) < a };
        then ex q being Point of TOP-REAL n st q=x & (|.q.|) < a;
        hence contradiction by A21;
      end;
      assume x in REAL n;
      hence thesis by A1,A23,XBOOLE_0:def 5;
    end;
    the carrier of TOP-REAL n=REAL n by EUCLID:22;
    then
A24: Q=the carrier of TOP-REAL n by A22;
    then LSeg(w1,w2) c=Q & LSeg(w2,w7) c=Q;
    hence thesis by A24;
  end;
end;
