
theorem Th49:
for f,g be sequence of ExtREAL, i,j be Nat st
 f is nonnegative &
 i >= j & (for n be Nat st n <> i & n <> j holds f.n = g.n)
 & f.i = g.j & f.j = g.i
 holds (Ser f).i = (Ser g).i
proof
    let f,g be sequence of ExtREAL, i,j be Nat;
    assume that
A1:  f is nonnegative and
A2:  i >= j and
A3:  for n be Nat st n <> i & n <> j holds f.n = g.n and
A4:  f.i = g.j and
A5:  f.j = g.i;

A6: for k be Element of NAT holds 0 <= g.k
    proof
     let k be Element of NAT;
     per cases;
     suppose k = i or k = j;
      hence 0 <= g.k by A1,A4,A5,SUPINF_2:51;
     end;
     suppose k <> i & k <> j; then
      g.k = f.k by A3;
      hence 0 <= g.k by A1,SUPINF_2:51;
     end;
    end; then
A7: g is nonnegative by SUPINF_2:39;

    per cases;
    suppose A8: j = 0;

     defpred P1[Nat] means $1 < i implies (Ser f).$1 + f.i = (Ser g).$1 + g.i;

     now assume 0 < i;
      f.i = (Ser g).0 & (Ser f).0 = g.i by A4,A5,A8,SUPINF_2:def 11;
      hence (Ser f).0 + f.i = (Ser g).0 + g.i;
     end; then
A9:  P1[0];

A10: for m be Nat st P1[m] holds P1[m+1]
     proof
      let m be Nat;
      assume A11: P1[m];
      assume A12: m+1 < i;

A13:  0 <= f.m & 0 <= f.(m+1) & 0 <= f.i by A1,SUPINF_2:51; then
A14:  0 <= (Ser f).m by A1,MEASURE7:2;

A15:  0 <= g.m & 0 <= g.(m+1) & 0 <= g.i by A6,SUPINF_2:39,51; then
A16:  0 <= (Ser g).m by A7,MEASURE7:2;

A17:  f.(m+1) = g.(m+1) by A3,A8,A12; then
A18:  (Ser f).(m+1) = g.(m+1) + (Ser f).m
    & (Ser g).(m+1) = f.(m+1) + (Ser g).m by SUPINF_2:def 11; then
      (Ser f).(m+1) + f.i
        = g.(m+1) + ((Ser f).m + f.i) by A13,A14,A15,XXREAL_3:44;
      hence (Ser f).(m+1) + f.i = (Ser g).(m+1) + g.i
        by A11,A12,A15,A16,A17,A18,XXREAL_3:44,NAT_1:13;
     end;
A19: for m be Nat holds P1[m] from NAT_1:sch 2(A9,A10);

     per cases;
     suppose A20: i=0; then
      (Ser f).i = f.0 & (Ser g).i = g.0 by SUPINF_2:def 11;
      hence (Ser f).i = (Ser g).i by A4,A8,A20;
     end;
     suppose i <> 0; then
      reconsider m = i-1 as Nat by NAT_1:20;
A21:  i = m+1; then
      m < i by NAT_1:13; then
      (Ser f).m + f.i = (Ser g).m + g.i by A19; then
      (Ser f).i = (Ser g).m + g.i by A21,SUPINF_2:def 11;
      hence (Ser f).i = (Ser g).i by A21,SUPINF_2:def 11;
     end;
    end;
    suppose A22: j <> 0; then
     reconsider m = j-1 as Nat by NAT_1:20;
A23: j = m+1; then
A24: m < j by NAT_1:13;
     for n be Nat st n < j holds f.n = g.n by A2,A3; then
A25: (Ser f).m = (Ser g).m by A24,Th48;

     per cases;
     suppose A26: j=i; then
      (Ser f).i = (Ser g).m + g.i by A4,A23,A25,SUPINF_2:def 11;
      hence (Ser f).i = (Ser g).i by A23,A26,SUPINF_2:def 11;
     end;

     suppose j <> i; then
A27:  j < i by A2,XXREAL_0:1;

      defpred P2[Nat] means
       j <= $1 < i implies (Ser f).$1 + f.i = (Ser g).$1 + g.i;

A28:  P2[0] by A22;
A29:  for k be Nat st P2[k] holds P2[k+1]
      proof
       let k be Nat;
       assume A30: P2[k];
       assume A31: j <= k+1 < i;

       per cases;
       suppose A32: j = k+1;

A33:    0 <= f.i & 0 <= g.i & 0 <= g.k by A1,A6,SUPINF_2:39,51; then
A34:    0 <= (Ser g).k by A7,MEASURE7:2;

        (Ser f).(k+1) + f.i
         = (Ser f).k + f.(k+1) + f.i by SUPINF_2:def 11; then
        (Ser f).(k+1) + f.i
         = (Ser g).k + f.i + g.i by A5,A25,A32,A33,A34,XXREAL_3:44;
        hence (Ser f).(k+1) + f.i = (Ser g).(k+1) + g.i
          by A4,A32,SUPINF_2:def 11;
       end;
       suppose j <> k+1; then
A35:    j < k+1 by A31,XXREAL_0:1;

A36:    0 <= f.(k+1) & 0 <= f.i & 0 <= f.k by A1,SUPINF_2:51; then
A37:    0 <= (Ser f).k by A1,MEASURE7:2;

A38:    0 <= g.(k+1) & 0 <= g.i & 0 <= g.k by A6,SUPINF_2:39,51; then
A39:    0 <= (Ser g).k by A7,MEASURE7:2;

        (Ser f).(k+1) = f.(k+1) + (Ser f).k by SUPINF_2:def 11; then
        (Ser f).(k+1) + f.i
          = f.(k+1) + ((Ser f).k + f.i) by A36,A37,XXREAL_3:44; then
        (Ser f).(k+1) + f.i
          = g.(k+1) + ((Ser g).k + g.i) by A3,A30,A31,A35,NAT_1:13; then
        (Ser f).(k+1) + f.i
          = g.(k+1) + (Ser g).k + g.i by A38,A39,XXREAL_3:44;
        hence (Ser f).(k+1) + f.i = (Ser g).(k+1) + g.i by SUPINF_2:def 11;
       end;
      end;
A40:  for k be Nat holds P2[k] from NAT_1:sch 2(A28,A29);

      reconsider k = i-1 as Nat by A27,NAT_1:20;
A41:  i = k+1; then
      j <= k < i by A27,NAT_1:13; then
      (Ser f).k + f.i = (Ser g).k + g.i by A40; then
      (Ser f).i = (Ser g).k + g.i by A41,SUPINF_2:def 11;
      hence (Ser f).i = (Ser g).i by A41,SUPINF_2:def 11;
     end;
    end;
end;
