reserve i,j,k,n,m for Nat;
reserve p,q for Point of TOP-REAL 2;
reserve G for Go-board;
reserve C for Subset of TOP-REAL 2;

theorem Th49:
  for f being non constant standard special_circular_sequence st 1
  <= i & i <= len GoB f & 1 <= j & j <= width GoB f holds <*(GoB f)*(i,j)*>
  is_in_the_area_of f
proof
  let f be non constant standard special_circular_sequence such that
A1: 1 <= i and
A2: i <= len GoB f and
A3: 1 <= j and
A4: j <= width GoB f;
  set G = GoB f;
A5: 1 <= width G by A3,A4,XXREAL_0:2;
A6: 1 <= len G by A1,A2,XXREAL_0:2;
A7: N-bound L~f = (G)*(1,width G)`2 by JORDAN5D:40
    .= (G)*(i,width G)`2 by A1,A2,A5,GOBOARD5:1;
A8: j = 1 or j > 1 by A3,XXREAL_0:1;
A9: S-bound L~f = (G)*(1,1)`2 by JORDAN5D:38
    .= (G)*(i,1)`2 by A1,A2,A5,GOBOARD5:1;
A10: i = 1 or i > 1 by A1,XXREAL_0:1;
A11: E-bound L~f = (G)*(len G,1)`1 by JORDAN5D:39
    .= (G)*(len G,j)`1 by A3,A4,A6,GOBOARD5:2;
A12: j = width G or j < width G by A4,XXREAL_0:1;
A13: i = len G or i < len G by A2,XXREAL_0:1;
  let n;
  set p = (GoB f)*(i,j);
  assume n in dom<*(GoB f)*(i,j)*>;
  then n in {1} by FINSEQ_1:2,38;
  then n = 1 by TARSKI:def 1;
  then
A14: <*p*>/.n = p by FINSEQ_4:16;
  W-bound L~f = G*(1,1)`1 by JORDAN5D:37
    .= G*(1,j)`1 by A3,A4,A6,GOBOARD5:2;
  hence thesis by A14,A10,A9,A8,A11,A13,A7,A12,GOBOARD5:3,4;
end;
