reserve AP for AffinPlane,
  a,a9,b,b9,c,c9,x,y,o,p,q,r,s for Element of AP,
  A,C,C9,D,K,M,N,P,T for Subset of AP;

theorem
  AP is satisfying_TDES_1 implies AP is satisfying_TDES_2
proof
  assume
A1: AP is satisfying_TDES_1;
    let K,o,a,b,c,a9,b9,c9;
    assume that
A2: K is being_line and
A3: o in K and
A4: c in K and
A5: c9 in K and
A6: not a in K and
A7: o<>c and
A8: a<>b and
A9: LIN o,a,a9 and
A10: LIN o,b,b9 and
A11: b,c // b9,c9 and
A12: a,c // a9,c9 and
A13: a,b // K;
    set A=Line(o,a), P=Line(o,b);
A14: A is being_line & a in A by A3,A6,AFF_1:24;
A15: o in A by A3,A6,AFF_1:24;
    then
A16: a9 in A by A3,A6,A9,A14,AFF_1:25;
A17: o<>b by A3,A6,A13,AFF_1:35;
    then
A18: P is being_line by AFF_1:24;
    consider N such that
A19: a9 in N and
A20: K // N by A2,AFF_1:49;
A21: N is being_line by A20,AFF_1:36;
    set T=Line(b9,c9);
A22: not b in K by A6,A13,AFF_1:35;
A23: b in P by A17,AFF_1:24;
A24: o in P by A17,AFF_1:24;
    then
A25: b9 in P by A10,A17,A18,A23,AFF_1:25;
    assume
A26: not a,b // a9,b9;
    then
A27: a9<>b9 by AFF_1:3;
A28: not b9 in K
    proof
A29:  a9,c9 // a,c by A12,AFF_1:4;
A30:  b9,c9 // c,b by A11,AFF_1:4;
      assume
A31:  b9 in K;
      then b9=o by A2,A3,A22,A18,A24,A23,A25,AFF_1:18;
      then c9 in A by A2,A3,A4,A5,A22,A15,A30,AFF_1:48;
      then a9=c9 or c in A by A14,A16,A29,AFF_1:48;
      hence contradiction by A2,A3,A4,A5,A6,A7,A27,A22,A15,A14,A31,A30,AFF_1:18
,48;
    end;
    then
A32: T is being_line by A5,AFF_1:24;
A33: b9 in T by A5,A28,AFF_1:24;
A34: c9 in T by A5,A28,AFF_1:24;
    not N // T
    proof
      assume N // T;
      then K // T by A20,AFF_1:44;
      hence contradiction by A5,A28,A33,A34,AFF_1:45;
    end;
    then consider x such that
A35: x in N and
A36: x in T by A32,A21,AFF_1:58;
    a9,x // K by A19,A20,A35,AFF_1:40;
    then
A37: a,b // a9,x by A2,A13,AFF_1:31;
    LIN c9,b9,x by A32,A33,A34,A36,AFF_1:21;
    then c9,b9 // c9,x by AFF_1:def 1;
    then b9,c9 // x,c9 by AFF_1:4;
    then b,c // x,c9 by A5,A11,A28,AFF_1:5;
    then LIN o,b,x by A1,A2,A3,A4,A5,A6,A7,A8,A9,A12,A13,A37;
    then x in P by A17,A18,A24,A23,AFF_1:25;
    then P=T by A26,A18,A25,A32,A33,A36,A37,AFF_1:18;
    then LIN c9,b9,b by A18,A23,A33,A34,AFF_1:21;
    then c9,b9 // c9,b by AFF_1:def 1;
    then b9,c9 // b,c9 by AFF_1:4;
    then b,c // b,c9 by A5,A11,A28,AFF_1:5;
    then LIN b,c,c9 by AFF_1:def 1;
    then
A38: LIN c,c9,b by AFF_1:6;
    then a,c // a9,c by A2,A4,A5,A12,A22,AFF_1:25;
    then c,a // c,a9 by AFF_1:4;
    then LIN c,a,a9 by AFF_1:def 1;
    then LIN a,a9,c by AFF_1:6;
    then
A39: a=a9 or c in A by A14,A16,AFF_1:25;
    b,c // b9,c by A2,A4,A5,A11,A22,A38,AFF_1:25;
    then c,b // c,b9 by AFF_1:4;
    then LIN c,b,b9 by AFF_1:def 1;
    then LIN b,b9,c by AFF_1:6;
    then b=b9 or c in P by A18,A23,A25,AFF_1:25;
    hence contradiction by A2,A3,A4,A6,A7,A26,A22,A18,A15,A14,A24,A23,A39,
AFF_1:2,18;
end;
