reserve
  X for non empty set,
  FX for Filter of X,
  SFX for Subset-Family of X;

theorem Th02:
  for X be set,SFX be Subset-Family of X holds SFX is cap-closed & X in SFX iff
  FinMeetCl SFX c= SFX
  proof
    let X be set,F be Subset-Family of X;
    hereby
    assume that
A1: F is cap-closed and
A2: X in F;
    now
      let x be object;
      assume
A3:   x in FinMeetCl F;
      then reconsider x1=x as Subset of X;
      consider Y be Subset-Family of X such that
A4:   Y c= F and
A5:   Y is finite and
A6:   x1=Intersect Y by A3,CANTOR_1:def 3;
      defpred P[Nat] means
      for Y be Subset-Family of X,x be Subset of X st
      Y c= F & card Y=$1 & x = Intersect Y holds
      x in F;
A7:   P[0]
      proof
        let Y be Subset-Family of X,x be Subset of X;
        assume that
        Y c= F and
A8:     card Y=0 and
A9:     x = Intersect Y;
A10:    Y={} by A8;
        reconsider x0=x as set;
        thus x in F by A9,A10,SETFAM_1:def 9,A2;
      end;
A11:  for k being Nat holds P[k] implies P[k+1]
      proof
        let k be Nat;
        assume
A12:    P[k];
        now
          let Y be Subset-Family of X,x be Subset of X;
          assume that
A13:      Y c= F and
A14:      card Y=k+1 and
A15:      x = Intersect Y;
          Y is finite set by A14;
          then consider x1 be Element of Y,C being Subset of Y such that
A16:      Y=C\/{x1} and
A17:      card C = k by A14,PRE_CIRC:24;
A18:      C c= F & card C=k by A13,A17;
          F c= bool X;
          then C c= bool X by A13;
          then reconsider C0=C as Subset-Family of X;
          per cases;
          suppose
A19:        C={};
            meet {x1}=x1 by SETFAM_1:10;
            then x=x1 by A15,A16,A19,SETFAM_1:def 9;
            hence x in F by A13,A16;
          end;
          suppose
A20:        C<>{};
            then meet(C\/{x1})=meet(C) /\ meet({x1}) by SETFAM_1:9;
            then
A21:        meet(Y)=meet C /\ x1 by A16,SETFAM_1:10;
            meet Y =Intersect(Y) by A16,SETFAM_1:def 9;
            then
A22:        Intersect(Y)=Intersect(C0)/\x1 by A20,A21,SETFAM_1:def 9;
A23:        Intersect(C0) in F by A12,A18;
            x1 in F by A13,A16;
            hence x in F by A22,A15,A23,A1;
          end;
        end;
        hence P[k+1];
      end;
A24:  for k being Nat holds P[k] from NAT_1:sch 2(A7,A11);
      reconsider CY=card Y as Nat by A5;
      P[CY] by A24;
      hence x in F by A4,A6;
    end;
    hence FinMeetCl F c= F;
  end;
  assume
A25:
  FinMeetCl F c= F;
  now
    let A,B be set;
    assume
A26:A in F & B in F;
    then A in bool X & B in bool X;
    then {A,B} c= bool X by TARSKI:def 2;
    then reconsider AB={A,B} as finite Subset-Family of X;
    AB c= F & AB is finite & meet AB=Intersect AB
    by A26,TARSKI:def 2,SETFAM_1:def 9;
    then meet AB in FinMeetCl F by CANTOR_1:def 3;
    then A/\B in FinMeetCl F by SETFAM_1:11;
    hence A/\B in F by A25;
  end;
  hence F is cap-closed & X in F by A25,CANTOR_1:8;
end;
