
theorem Th4:
  for vseq be sequence of Complex_linfty_Space st vseq is
  Cauchy_sequence_by_Norm holds vseq is convergent
proof
  let vseq be sequence of Complex_linfty_Space such that
A1: vseq is Cauchy_sequence_by_Norm;
  defpred P[object,object] means ex i be Nat st $1=i & ex cseqi be
Complex_Sequence st (for n be Nat holds cseqi.n=(seq_id(vseq.n)).i)
  & cseqi is convergent & $2 = lim cseqi;
A2: for x be object st x in NAT ex y be object st y in COMPLEX & P[x,y]
  proof
    let x be object;
    assume x in NAT;
    then reconsider i=x as Nat;
    deffunc F(Nat) = (seq_id(vseq.$1)).i;
    consider cseqi be Complex_Sequence such that
A3: for n be Nat holds cseqi.n = F(n) from COMSEQ_1:sch 1;
    take lim cseqi;
    thus lim cseqi in COMPLEX by XCMPLX_0:def 2;
    now
      let e be Real such that
A4:   e > 0;
      thus ex k be Nat st for m be Nat st k <= m holds
      |.(cseqi.m -cseqi.k).| < e
      proof
       reconsider ee=e as Real;
        consider k be Nat such that
A5:     for n, m be Nat st n >= k & m >= k holds ||.(vseq.n
        ) - (vseq.m).|| < ee by A1,A4,CSSPACE3:8;
        take k;
        let m be Nat such that
A6:     k<=m;
A7: i in NAT by ORDINAL1:def 12;
        seq_id((vseq.m) - (vseq.k)) = seq_id(seq_id(vseq.m)-seq_id(vseq.k
        )) by Th2
          .= seq_id(vseq.m)+-seq_id(vseq.k);
        then (seq_id((vseq.m) - (vseq.k))).i = (seq_id(vseq.m)).i+(-seq_id(
        vseq.k)).i by VALUED_1:1,A7
          .=(seq_id(vseq.m)).i+(-(seq_id(vseq.k)).i) by VALUED_1:8
          .=(seq_id(vseq.m)).i-(seq_id(vseq.k)).i
          .=cseqi.m -(seq_id(vseq.k)).i by A3
          .=cseqi.m - cseqi.k by A3;
        then
A8:     |.
(cseqi.m-cseqi.k).| = |.(seq_id((vseq.m)-(vseq.k))).| .i by VALUED_1:18;
        seq_id((vseq.m)-(vseq.k)) is bounded by Def1;
        then |.(seq_id((vseq.m)-(vseq.k))).| is bounded by Lm8;
        then
A9:     |.(seq_id((vseq.m) - (vseq.k))).| .i <=
upper_bound rng |.(seq_id((vseq.m
        ) - (vseq.k))).| by Lm2;
        ||.(vseq.m) - (vseq.k).|| =
        upper_bound rng |.(seq_id((vseq.m) - (vseq.k)))
        .| by Th2;
        then upper_bound rng |.(seq_id((vseq.m) - (vseq.k))).| < e by A5,A6;
        hence thesis by A9,A8,XXREAL_0:2;
      end;
    end;
    then cseqi is convergent by COMSEQ_3:46;
    hence thesis by A3;
  end;
  consider f be sequence of COMPLEX such that
A10: for x be object st x in NAT holds P[x,f.x] from FUNCT_2:sch 1(A2);
  reconsider tseq=f as Complex_Sequence;
A11: now
    let i be Nat;
    reconsider x=i as set;
 i in NAT by ORDINAL1:def 12;
    then
    ex i0 be Nat st x=i0 & ex cseqi be Complex_Sequence st (
    for n be Nat holds cseqi.n=(seq_id(vseq.n)).i0 ) & cseqi is
    convergent & f.x=lim cseqi by A10;
    hence
    ex cseqi be Complex_Sequence st ( for n be Nat holds cseqi
    .n=(seq_id(vseq.n)).i ) & cseqi is convergent & tseq.i=lim cseqi;
  end;
A12: for e be Real st e >0
  ex k be Nat st for n be Nat
st n >= k holds |.(seq_id tseq-seq_id(vseq.n)).| is bounded &
upper_bound rng |.(seq_id
  tseq-seq_id(vseq.n)).| <= e
  proof
    let e be Real such that
A13: e > 0;
    consider k be Nat such that
A14: for n, m be Nat st n >= k & m >= k holds ||.(vseq.n) -
    (vseq.m).|| < e by A1,A13,CSSPACE3:8;
A15: for m,n be Nat st n >= k & m >= k holds |.seq_id((vseq.n)
    - (vseq.m)).| is bounded &
    upper_bound rng |.seq_id((vseq.n) - (vseq.m)).| < e
    proof
      let m,n be Nat;
      assume n >= k & m >= k;
      then ||.(vseq.n) - (vseq.m).|| < e by A14;
      then
A16:  (the normF of Complex_linfty_Space).((vseq.n) - (vseq.m)) < e;
      seq_id((vseq.n) - (vseq.m)) is bounded by Def1;
      hence thesis by A16,Def2,Lm8;
    end;
A17: for n be Nat for i be Nat holds for rseq be
Real_Sequence st ( for m be Nat holds rseq.m=|.(seq_id(vseq.m-vseq.n
)).| .i ) holds rseq is convergent & lim rseq = |.((seq_id tseq -seq_id(vseq.n)
    )).| .i
    proof
      let n be Nat;
A18:  for m,k be Nat holds seq_id((vseq.m) - (vseq.k)) =
      seq_id(vseq.m)-seq_id(vseq.k)
      proof
        let m,k be Nat;
        seq_id((vseq.m) - (vseq.k)) = seq_id(seq_id(vseq.m)-seq_id(vseq.k
        )) by Th2;
        hence thesis;
      end;
      now
        let i be Nat;
        consider cseqi be Complex_Sequence such that
A19:    for n be Nat holds cseqi.n=(seq_id(vseq.n)).i and
A20:    cseqi is convergent & tseq.i=lim cseqi by A11;
        now
          let rseq be Real_Sequence such that
A21:      for m be Nat holds rseq.m=|.(seq_id(vseq.m-vseq. n)).| .i;
A22:      now
            let m be Nat;
A23:        seq_id(vseq.m - vseq.n) = seq_id(vseq.m)-seq_id(vseq.n) by A18;
            thus rseq.m=|.(seq_id(vseq.m-vseq.n)).| .i by A21
              .=|.((seq_id(vseq.m-vseq.n)).i).| by VALUED_1:18
              .=|.((seq_id(vseq.m)).i -(seq_id(vseq.n)).i).| by A23,Lm11
              .= |.(cseqi.m -(seq_id(vseq.n)).i) .| by A19;
          end;
          |.(tseq.i-(seq_id(vseq.n)).i).| = |.((tseq-(seq_id(vseq.n))).i)
          .| by Lm11
            .= |.((seq_id tseq -seq_id(vseq.n))).| .i by VALUED_1:18;
          hence
          rseq is convergent & lim rseq = |.(seq_id tseq -seq_id(vseq.n))
          .| .i by A20,A22,CSSPACE3:1;
        end;
        hence
        for rseq be Real_Sequence st ( for m be Nat holds rseq
.m=|.(seq_id(vseq.m-vseq.n)).| .i ) holds rseq is convergent & lim rseq = |.(
        seq_id tseq -seq_id(vseq.n)).| .i;
      end;
      hence thesis;
    end;
    for n be Nat st n >= k holds |.(seq_id tseq-seq_id(vseq.n)
    ).| is bounded & upper_bound rng |.(seq_id tseq-seq_id(vseq.n)).| <= e
    proof
      let n be Nat such that
A24:  n >= k;
A25:  for i be Nat holds |.((seq_id tseq -seq_id(vseq.n))).| .
      i <= e
      proof
        let i be Nat;
        deffunc F(Nat)= |.(seq_id((vseq.$1) - (vseq.n))).| .i;
        consider rseq be Real_Sequence such that
A26:    for m be Nat holds rseq.m = F(m) from SEQ_1:sch 1;
A27:    for m be Nat st m >= k holds rseq.m <= e
        proof
          let m be Nat;
A28:      rseq.m = |.(seq_id((vseq.m) - (vseq.n))).| .i by A26;
          assume
A29:      m >= k;
          then |.(seq_id((vseq.m) - (vseq.n))).| is bounded by A15,A24;
          then
A30:      |.(seq_id((vseq.m) - (vseq.n))).| .i <=
upper_bound rng |.seq_id((vseq.m
          ) - (vseq.n)).| by Lm2;
          upper_bound rng |. seq_id((vseq.m) - (vseq.n)).| <= e by A15,A24,A29;
          hence thesis by A30,A28,XXREAL_0:2;
        end;
        rseq is convergent & lim rseq = |.(seq_id tseq-seq_id(vseq.n)).|
        .i by A17,A26;
        hence thesis by A27,RSSPACE2:5;
      end;
A31:  0 + e < 1 + e by XREAL_1:8;
      now
        let i be Nat;
        |.((seq_id tseq -seq_id(vseq.n))).| .i <= e by A25;
        then |.(((seq_id tseq -seq_id(vseq.n))).i).| <= e by VALUED_1:18;
        hence |.(((seq_id tseq -seq_id(vseq.n))).i).| <e+1 by A31,XXREAL_0:2;
      end;
      then seq_id tseq -seq_id(vseq.n) is bounded by A13,COMSEQ_2:8;
      hence thesis by A25,Lm1,Lm8;
    end;
    hence thesis;
  end;
A32: seq_id tseq is bounded
  proof
    consider m be Nat such that
A33: for n be Nat st n >= m holds |.(seq_id tseq -seq_id(
vseq.n)).| is bounded & upper_bound rng |.(seq_id tseq -seq_id(vseq.n)).|
 <= jj by A12;
A34: |.(seq_id tseq -seq_id(vseq.m)).| is bounded by A33;
    set d=|.seq_id tseq.|;
    set b=|.seq_id(vseq.m).|;
    set a=|.(seq_id tseq -seq_id(vseq.m)).|;
    seq_id(vseq.m) is bounded by Def1;
    then
A35: |.seq_id (vseq.m).| is bounded by Lm8;
A36: for i be Nat holds d.i <= (a+b).i
    proof
      let i be Nat;
A37: i in NAT by ORDINAL1:def 12;
A38:  b.i=|.((seq_id(vseq.m)).i).| & d.i=|.((seq_id tseq).i).| by VALUED_1:18;
      a.i = |.((seq_id tseq+-seq_id(vseq.m)).i).| by VALUED_1:18
        .= |.((seq_id tseq).i+(-seq_id(vseq.m)).i).| by VALUED_1:1,A37
        .= |.((seq_id tseq).i+(-(seq_id(vseq.m)).i)).| by VALUED_1:8
        .= |.((seq_id tseq).i-(seq_id(vseq.m)).i).|;
      then d.i-b.i <= a.i by A38,COMPLEX1:59;
      then d.i-b.i+b.i<= a.i + b.i by XREAL_1:6;
      hence thesis by SEQ_1:7;
    end;
    d is bounded
    proof
      reconsider r=upper_bound rng (a+b)+1 as Real;
      b.1=|.( (seq_id(vseq.m)).1 ).| by VALUED_1:18;
      then
A39:  0<= b.1 by COMPLEX1:46;
A40:  upper_bound( rng(a+b) ) +0 < upper_bound( rng(a+b) )+1 by XREAL_1:8;
A41:  now
        let i be Nat;
        d.i <= (a+b).i & (a+b).i <= upper_bound rng (a+b) by A34,A35,A36,Lm2;
        then
A42:    d.i <= upper_bound rng (a+b) by XXREAL_0:2;
        d.i=|.((seq_id tseq).i).| by VALUED_1:18;
        hence |.((seq_id tseq).i).| <r by A40,A42,XXREAL_0:2;
      end;
      a.1=|.((seq_id tseq -seq_id(vseq.m)).1).| by VALUED_1:18;
      then (a+b).1 =a.1 + b.1 & 0<= a.1 by COMPLEX1:46,SEQ_1:7;
      then 0 <= upper_bound rng(a+b) by A34,A35,A39,Lm2;
      then seq_id tseq is bounded by A41,COMSEQ_2:8;
      hence thesis by Lm8;
    end;
    hence thesis by Lm9;
  end;
A43: tseq in the_set_of_ComplexSequences by FUNCT_2:8;
  then reconsider tv=tseq as Point of Complex_linfty_Space by A32,Def1;
  ex tv be Point of Complex_linfty_Space st
    for e1 be Real st e1 > 0 ex m
  be Nat st for n be Nat st n >= m holds ||.(vseq.n) - tv
  .|| < e1
  proof
    take tv;
    let e1 be Real such that
A44: e1 > 0;
    set e=e1/2;
    reconsider ee=e as Real;
    consider m be Nat such that
A45: for n be Nat st n >= m holds |.(seq_id tseq-seq_id(
vseq.n)).| is bounded & upper_bound rng |.(seq_id tseq-seq_id(vseq.n)).|
 <= ee by A12,A44;
A46: e < e1 by A44,XREAL_1:216;
    now
      reconsider u=tseq as VECTOR of Complex_linfty_Space by A32,A43,Def1;
      let n be Nat;
      assume n >= m;
      then
A47:  upper_bound rng( |.(seq_id tseq-seq_id(vseq.n)).|) <= e by A45;
      reconsider v=vseq.n as VECTOR of Complex_linfty_Space;
      seq_id(u-v) = u-v by Th2;
      then upper_bound rng |.seq_id(u-v).| =
      upper_bound rng |.(seq_id tseq-seq_id(vseq.n)).|
      by Th2;
      then
A48:  (the normF of Complex_linfty_Space).(u-v) <= e by A47,Def2;
      ||.(vseq.n) - tv.|| =||.-(tv-(vseq.n)).|| by RLVECT_1:33
        .=||.tv-(vseq.n).|| by CLVECT_1:103;
      then ||.(vseq.n) - tv.|| <= e by A48;
      hence ||.(vseq.n) - tv.|| < e1 by A46,XXREAL_0:2;
    end;
    hence thesis;
  end;
  hence thesis by CLVECT_1:def 15;
end;
