 reserve Rseq, Rseq1, Rseq2 for Function of [:NAT,NAT:],REAL;

theorem
Rseq is non-decreasing & Rseq is P-convergent implies
  (for n,m being Nat holds Rseq.(n,m) <= P-lim Rseq)
proof
   assume a1: Rseq is non-decreasing & Rseq is P-convergent;
   hereby let n,m be Nat;
    reconsider n1=n, m1=m as Element of NAT by ORDINAL1:def 12;
    Rseq.(n,m) is Element of REAL by XREAL_0:def 1; then
    reconsider Rseq1 = [:NAT,NAT:] --> Rseq.(n,m)
      as Function of [:NAT,NAT:],REAL by FUNCOP_1:46;
    deffunc F2(Element of NAT,Element of NAT) = Rseq.(n+$1,m+$2);
    consider Rseq2 be Function of [:NAT,NAT:],REAL such that
a4:  for i be Element of NAT for j be Element of NAT holds
      Rseq2.(i,j) = F2(i,j) from BINOP_1:sch 4;
a5: now let i,j be Nat;
a6:  n+i>=n & m+j>=m by NAT_1:11;
     i in NAT & j in NAT by ORDINAL1:def 12; then
     Rseq1.(i,j) = Rseq.(n,m) & Rseq2.(i,j) = Rseq.(n+i,m+j)
       by a4,FUNCOP_1:70;
     hence Rseq1.(i,j) <= Rseq2.(i,j) by a1,a6;
    end;
    reconsider r = Rseq.(n,m) as Element of REAL by XREAL_0:def 1;
    Rseq1 = [:NAT,NAT:] --> r; then
a7: Rseq1 is P-convergent & P-lim Rseq1 = Rseq.(n,m) by DBLSEQ_1:2;
    deffunc N(Element of NAT) = n+$1;
    consider N be Function of NAT,NAT such that
b1:  for i be Element of NAT holds N.i = N(i) from FUNCT_2:sch 4;
    now let k be Nat;
     k is Element of NAT by ORDINAL1:def 12; then
b2:  N.k = n+k & N.(k+1) = n+(k+1) by b1;
     k < k+1 by NAT_1:13;
     hence N.k < N.(k+1) by b2,XREAL_1:6;
    end; then
    reconsider N as increasing sequence of NAT by VALUED_1:def 13;
    deffunc M(Element of NAT) = m+$1;
    consider M be Function of NAT,NAT such that
c1:  for j be Element of NAT holds M.j = M(j) from FUNCT_2:sch 4;
    now let k be Nat;
     k is Element of NAT by ORDINAL1:def 12; then
c2:  M.k = m+k & M.(k+1) = m+(k+1) by c1;
     k < k+1 by NAT_1:13;
     hence M.k < M.(k+1) by c2,XREAL_1:6;
    end; then
    reconsider M as increasing sequence of NAT by VALUED_1:def 13;
    for i,j be Nat holds Rseq2.(i,j) = Rseq.(N.i,M.j)
    proof
     let i,j be Nat;
c5:  i in NAT & j in NAT by ORDINAL1:def 12; then
     N.i = n+i & M.j = m+j by b1,c1;
     hence Rseq2.(i,j) = Rseq.(N.i,M.j) by c5,a4;
    end; then
    Rseq2 is subsequence of Rseq by DBLSEQ_1:def 14; then
    Rseq2 is P-convergent & P-lim Rseq2 = P-lim Rseq by a1,DBLSEQ_1:17;
    hence Rseq.(n,m) <= P-lim Rseq by a5,a7,DBLSEQ_1:15;
   end;
end;
