reserve x for Real,

  Z for open Subset of REAL;

theorem
  Z c= dom (cot*tan) implies cot*tan is_differentiable_on Z & for x st x
  in Z holds((cot*tan)`|Z).x = (-1/(sin.(tan.x))^2)*(1/(cos.x)^2)
proof
  assume
A1: Z c= dom (cot*tan);
A2: for x st x in Z holds sin.(tan.x) <> 0
  proof
    let x;
    assume x in Z;
    then tan.x in dom (cot) by A1,FUNCT_1:11;
    hence thesis by FDIFF_8:2;
  end;
A3: for x st x in Z holds cos.x <> 0
  proof
    let x;
    assume x in Z;
    then x in dom (sin/cos) by A1,FUNCT_1:11;
    hence thesis by FDIFF_8:1;
  end;
A4: for x st x in Z holds cot*tan is_differentiable_in x
  proof
    let x;
    assume
A5: x in Z;
    then sin.(tan.x)<>0 by A2;
    then
A6: cot is_differentiable_in tan.x by FDIFF_7:47;
    cos.x <> 0 by A3,A5;
    then tan is_differentiable_in x by FDIFF_7:46;
    hence thesis by A6,FDIFF_2:13;
  end;
  then
A7: cot*tan is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((cot*tan)`|Z).x=(-1/(sin.(tan.x))^2)*(1/(cos.x) ^2)
  proof
    let x;
    assume
A8: x in Z;
    then
A9: sin.(tan.x)<>0 by A2;
    then
A10: cot is_differentiable_in tan.x by FDIFF_7:47;
A11: cos.x<>0 by A3,A8;
    then tan is_differentiable_in x by FDIFF_7:46;
    then diff(cot*tan,x) = diff(cot, tan.x)*diff(tan,x) by A10,FDIFF_2:13
      .=(-1/(sin.(tan.x))^2)* diff(tan,x) by A9,FDIFF_7:47
      .=(-1/(sin.(tan.x))^2)*(1/(cos.x)^2) by A11,FDIFF_7:46;
    hence thesis by A7,A8,FDIFF_1:def 7;
  end;
  hence thesis by A1,A4,FDIFF_1:9;
end;
