reserve p,q for Point of TOP-REAL 2,
  i,i1,i2,j,j1,j2,k for Nat,
  r,s for Real,
  G for Matrix of TOP-REAL 2;

theorem Th4:
  G is Y_increasing-in-line &
  1 <= j1 & j1 < j2 & j2 <= width G & 1 <= i & i <= len G
  implies G*(i,j1)`2 < G*(i,j2)`2
proof
  assume that
A1: G is Y_increasing-in-line and
A2: 1 <= j1 and
A3: j1 < j2 and
A4: j2 <= width G and
A5: 1 <= i and
A6: i <= len G;
  i in dom G by A5,A6,FINSEQ_3:25;
  then
A7: Y_axis(Line(G,i)) is increasing by A1;
  reconsider c = Line(G,i) as FinSequence of TOP-REAL 2;
A8: j1 <= width G by A3,A4,XXREAL_0:2;
  then
A9: j1 in Seg width G by A2,FINSEQ_1:1;
A10: 1 <= j2 by A2,A3,XXREAL_0:2;
  then
A11: j2 in Seg width G by A4,FINSEQ_1:1;
A12: len c = width G by MATRIX_0:def 7;
  then j1 in dom c by A2,A8,FINSEQ_3:25;
  then
A13: c/.j1 = c.j1 by PARTFUN1:def 6;
  j2 in dom c by A4,A10,A12,FINSEQ_3:25;
  then
A14: c/.j2 = c.j2 by PARTFUN1:def 6;
A15: len Y_axis Line(G,i) = len c by GOBOARD1:def 2;
  then
A16: j1 in dom(Y_axis Line(G,i)) by A2,A8,A12,FINSEQ_3:25;
A17: G*(i,j1)`2 = (c/.j1)`2 by A9,A13,MATRIX_0:def 7
    .= (Y_axis Line(G,i)).j1 by A16,GOBOARD1:def 2;
A18: j2 in dom(Y_axis Line(G,i)) by A4,A10,A12,A15,FINSEQ_3:25;
  then (Y_axis Line(G,i)).j2 = (c/.j2)`2 by GOBOARD1:def 2
    .= G*(i,j2)`2 by A11,A14,MATRIX_0:def 7;
  hence thesis by A3,A7,A16,A17,A18;
end;
