reserve C for Simple_closed_curve,
  P for Subset of TOP-REAL 2,
  p for Point of TOP-REAL 2,
  n for Element of NAT;

theorem Th4: :: P is an open north halfline
  for s,t1 being Real, P being Subset of TOP-REAL 2 st P = {
  |[ s,t ]| where t is Real : t1 < t } holds P is convex
proof
  let s,t1 be Real, P be Subset of TOP-REAL 2;
  assume
A1: P = { |[ s,t ]| where t is Real : t1<t };
  let w1,w2 be Point of TOP-REAL 2 such that
A2: w1 in P and
A3: w2 in P;
  consider t3 being Real such that
A4: |[ s,t3 ]|=w1 and
A5: t1<t3 by A1,A2;
A6: w1`1=s by A4,EUCLID:52;
  let x be object;
  assume x in LSeg(w1,w2);
  then consider l being Real such that
A7: x = (1-l)*w1 + l*w2 and
A8: 0 <= l & l <= 1;
  set w = (1-l)*w1 + l*w2;
A9: w = |[((1-l)*w1)`1+(l*w2)`1,((1-l)*w1)`2+ (l*w2)`2]| by EUCLID:55;
  consider t4 being Real such that
A10: |[ s,t4 ]|=w2 and
A11: t1<t4 by A1,A3;
A12: w2`1=s by A10,EUCLID:52;
A13: l*w2=|[ l*w2`1 ,l*w2`2 ]| by EUCLID:57;
  then
A14: (l*w2)`1=l*w2`1 by EUCLID:52;
A15: (l*w2)`2=l*w2`2 by A13,EUCLID:52;
A16: (1-l)*w1=|[ (1-l)*w1`1 ,(1-l)*w1`2 ]| by EUCLID:57;
  then ((1-l)*w1)`2= (1-l)*w1`2 by EUCLID:52;
  then
A17: w`2=(1-l)* w1`2+ l* w2`2 by A9,A15,EUCLID:52;
A18: w2`2=t4 by A10,EUCLID:52;
  ((1-l)*w1)`1= (1-l)*w1`1 by A16,EUCLID:52;
  then
A19: w = |[w`1, w`2]| & w`1 = s - 0 by A6,A12,A9,A14,EUCLID:52,53;
  w1`2=t3 by A4,EUCLID:52;
  then t1 < w`2 by A5,A11,A18,A8,A17,XREAL_1:175;
  hence thesis by A1,A7,A19;
end;
