reserve p1, p2 for Point of TOP-REAL 2,
  C for Simple_closed_curve,
  P for Subset of TOP-REAL 2;

theorem Th4:
  for A being Real st p1,p2 realize-max-dist-in P holds (Rotate A).
  p1,(Rotate A).p2 realize-max-dist-in (Rotate A).:P
proof
  let A be Real;
  reconsider f=Rotate A as Function of TopSpaceMetr Euclid 2, TopSpaceMetr
  Euclid 2 by Lm1;
  set C=P;
A1: dom Rotate A = the carrier of TOP-REAL 2 by FUNCT_2:def 1;
  assume
A2: p1,p2 realize-max-dist-in C;
  then p1 in C & p2 in C;
  hence (Rotate A).p1 in (Rotate A).:C & (Rotate A).p2 in (Rotate A).:C by A1,
FUNCT_1:def 6;
  let x, y be Point of TOP-REAL 2 such that
A3: x in (Rotate A).:C and
A4: y in (Rotate A).:C;
  f is isometric by Th2;
  then consider g being isometric Function of Euclid 2,Euclid 2 such that
A5: f=g;
  consider yy being object such that
A6: yy in dom Rotate A and
A7: yy in C and
A8: (Rotate A).yy=y by A4,FUNCT_1:def 6;
  reconsider yy as Point of TOP-REAL 2 by A6;
  consider xx being object such that
A9: xx in dom Rotate A and
A10: xx in C and
A11: (Rotate A).xx=x by A3,FUNCT_1:def 6;
  reconsider xx as Point of TOP-REAL 2 by A9;
  reconsider p19=p1,p29=p2,xx9=xx,yy9=yy as Point of Euclid 2 by EUCLID:67;
  dist(p1,p2) >= dist(xx,yy) by A2,A10,A7;
  then dist(p19,p29) >= dist(xx,yy) by TOPREAL6:def 1;
  then dist(p19,p29) >= dist(xx9,yy9) by TOPREAL6:def 1;
  then dist(g.p19,g.p29) >= dist(xx9,yy9) by VECTMETR:def 3;
  then dist(g.p19,g.p29) >= dist(g.xx9,g.yy9) by VECTMETR:def 3;
  then dist((Rotate A).p1,(Rotate A).p2) >= dist(g.xx9,g.yy9) by A5,
TOPREAL6:def 1;
  hence thesis by A11,A8,A5,TOPREAL6:def 1;
end;
