reserve p,p1,p2,p3,q for Point of TOP-REAL 2;

theorem
  for P being compact non empty Subset of TOP-REAL 2 st P is
  being_simple_closed_curve holds Segment(W-min(P),E-max(P),P)=Upper_Arc(P) &
  Segment(E-max(P),W-min(P),P)=Lower_Arc(P)
proof
  let P be compact non empty Subset of TOP-REAL 2;
  assume
A1: P is being_simple_closed_curve;
  then
A2: Upper_Arc(P) is_an_arc_of W-min(P),E-max(P) by JORDAN6:def 8;
A3: {p1: LE E-max(P),p1,P or E-max(P) in P & p1=W-min(P)} = Lower_Arc(P)
  proof
A4: {p1: LE E-max(P),p1,P or E-max(P) in P & p1=W-min(P)} c= Lower_Arc(P)
    proof
      let x be object;
      assume x in {p1: LE E-max(P),p1,P or E-max(P) in P & p1=W-min(P)};
      then consider p1 such that
A5:   p1=x and
A6:   LE E-max(P),p1,P or E-max(P) in P & p1=W-min(P);
      per cases by A6;
      suppose
A7:     LE E-max(P),p1,P;
        per cases by A5,A7,JORDAN6:def 10;
        suppose
          x in Lower_Arc(P);
          hence thesis;
        end;
        suppose
A8:       E-max(P) in Upper_Arc(P) & p1 in Upper_Arc(P) & LE E-max(P)
          ,p1,Upper_Arc(P),W-min(P),E-max(P);
A9:       Upper_Arc(P) is_an_arc_of W-min(P),E-max(P) by A1,JORDAN6:50;
          then LE p1,E-max(P),Upper_Arc(P),W-min(P),E-max(P) by A8,JORDAN5C:10;
          then
A10:      p1=E-max(P) by A8,A9,JORDAN5C:12;
          Lower_Arc(P) is_an_arc_of E-max(P),W-min(P) by A1,JORDAN6:def 9;
          hence thesis by A5,A10,TOPREAL1:1;
        end;
      end;
      suppose
        E-max(P) in P & p1=W-min(P);
        then x in {W-min(P),E-max(P)} by A5,TARSKI:def 2;
        then x in Upper_Arc(P) /\ Lower_Arc(P) by A1,JORDAN6:def 9;
        hence thesis by XBOOLE_0:def 4;
      end;
    end;
    Lower_Arc(P) c= {p1: LE E-max(P),p1,P or E-max(P) in P & p1=W-min(P) }
    proof
      let x be object;
      assume
A11:  x in Lower_Arc(P);
      then reconsider p2=x as Point of TOP-REAL 2;
      Upper_Arc(P) is_an_arc_of W-min(P),E-max(P) by A1,JORDAN6:50;
      then
      not (E-max P in P & p2=W-min P) implies E-max P in Upper_Arc P & p2
      in Lower_Arc P & not p2=W-min P by A11,SPRECT_1:14,TOPREAL1:1;
      then LE E-max(P),p2,P or E-max P in P & p2=W-min P by JORDAN6:def 10;
      hence thesis;
    end;
    hence thesis by A4;
  end;
A12: E-max(P)<>W-min(P) by A1,TOPREAL5:19;
  {p: LE W-min(P),p,P & LE p,E-max(P),P} = Upper_Arc(P)
  proof
A13: {p: LE W-min(P),p,P & LE p,E-max(P),P} c= Upper_Arc(P)
    proof
      let x be object;
      assume x in {p: LE W-min(P),p,P & LE p,E-max(P),P};
      then consider p such that
A14:  p=x and
      LE W-min(P),p,P and
A15:  LE p,E-max(P),P;
      per cases by A15,JORDAN6:def 10;
      suppose
        p in Upper_Arc(P) & E-max(P) in Lower_Arc(P) & not E-max(P)= W-min(P);
        hence thesis by A14;
      end;
      suppose
        p in Upper_Arc(P) & E-max(P) in Upper_Arc(P) & LE p,E-max(P),
        Upper_Arc(P),W-min(P),E-max(P);
        hence thesis by A14;
      end;
      suppose
A16:    p in Lower_Arc(P) & E-max(P) in Lower_Arc(P) & not E-max(P)=
        W-min(P) & LE p,E-max(P),Lower_Arc(P),E-max(P),W-min(P);
        Lower_Arc(P) is_an_arc_of E-max(P),W-min(P) by A1,JORDAN6:def 9;
        then p=E-max(P) by A16,JORDAN6:54;
        hence thesis by A2,A14,TOPREAL1:1;
      end;
    end;
    Upper_Arc(P) c= {p: LE W-min(P),p,P & LE p,E-max(P),P}
    proof
      let x be object;
      assume
A17:  x in Upper_Arc(P);
      then reconsider p2=x as Point of TOP-REAL 2;
      E-max(P) in Lower_Arc(P) by A1,Th1;
      then
A18:  LE p2,E-max(P),P by A12,A17,JORDAN6:def 10;
A19:  W-min(P) in Upper_Arc(P) by A1,Th1;
      LE W-min(P),p2,Upper_Arc(P),W-min(P),E-max(P) by A2,A17,JORDAN5C:10;
      then LE W-min(P),p2,P by A17,A19,JORDAN6:def 10;
      hence thesis by A18;
    end;
    hence thesis by A13;
  end;
  hence thesis by A12,A3,Def1;
end;
