reserve x,y for object,
  N for Element of NAT,
  c,i,j,k,m,n for Nat,
  D for non empty set,
  s for Element of 2Set Seg (n+2),
  p for Element of Permutations(n) ,
  p1, q1 for Element of Permutations(n+1),
  p2 for Element of Permutations(n +2),
  K for Field,
  a for Element of K,
  f for FinSequence of K,
  A for (Matrix of K),
  AD for Matrix of n,m,D,
  pD for FinSequence of D,
  M for Matrix of n,K;

theorem Th4:
  for i be Nat st len A > 1 holds width A = width DelLine(A,i)
proof
  let i be Nat;
  assume
A1: len A>1;
  per cases;
  suppose
    i in dom A;
    then consider m be Nat such that
A2: len A = m + 1 and
A3: len Del(A,i) = m by FINSEQ_3:104;
A4: m>=1 by A1,A2,NAT_1:13;
    then
A5: m in dom Del(A,i) by A3,FINSEQ_3:25;
    then
A6: DelLine(A,i).m in rng Del(A,i) by FUNCT_1:def 3;
A7: rng Del(A,i) c= rng A by FINSEQ_3:106;
A8: DelLine(A,i).m=Line(DelLine(A,i),m) by A5,MATRIX_0:60;
    A is Matrix of len A,width A,K by A1,MATRIX_0:20;
    then len Line(DelLine(A,i),m)=width A by A6,A8,A7,MATRIX_0:def 2;
    hence thesis by A3,A4,A6,A8,MATRIX_0:def 3;
  end;
  suppose
    not i in dom A;
    hence thesis by FINSEQ_3:104;
  end;
end;
