
theorem Th4:
  for X,Y be RealNormSpace,
      f be LinearOperator of X,Y,
      x be Point of X holds
    f is_continuous_in x iff f is_continuous_in 0.X
proof
  let X,Y be RealNormSpace,
      f be LinearOperator of X,Y,
      x be Point of X;
A1: dom f =the carrier of X by FUNCT_2:def 1;
A2: 0.Y=f/.0.X by Th3;
  hereby assume A3:f is_continuous_in x;
    now let r be Real;
      assume 0 < r;
      then consider s be Real such that
  A4: 0<s & for x1 be Point of X st x1 in dom f &
      ||. x1- x .|| < s holds ||. f/.x1 - f/.x .|| < r by A3,NFCONT_1:7;
      take s;
      thus 0 < s by A4;
      let x1 be Point of X;
      assume A5: x1 in dom f & ||. x1- 0.X .|| < s;
      set y1= x1+x;
    A6: y1- x = x1+(x- x) by RLVECT_1:28
             .= x1+0.X by RLVECT_1:15
             .= x1 by RLVECT_1:4; then
    A7: ||. y1- x .|| < s by A5, RLVECT_1:13;
        f/.y1 - f/.x =f.(y1) +(-1) * f.x by RLVECT_1:16
                    .=f.(y1) + f.((-1)*x) by LOPBAN_1:def 5
                    .= f.(y1 + (-1)*x) by VECTSP_1:def 20
                    .= f.(y1-x) by RLVECT_1:16
                    .= f/.x1 - f/.(0.X) by A6, A2,RLVECT_1:13;
        hence ||. f/.x1 - f/.(0.X) .|| < r by A7,A4,A1;
  end;
  hence f is_continuous_in 0.X by A1,NFCONT_1:7;
 end;
  assume A8:f is_continuous_in 0.X;
  now let r be Real;
    assume 0 < r;
    then consider s be Real such that
   A9: 0<s & for x1 be Point of X st x1 in dom f &
       ||. x1- 0.X .|| < s holds ||. f/.x1 - f/.0.X .|| < r by A8,NFCONT_1:7;
     take s;
     thus 0 < s by A9;
     thus for x1 be Point of X st x1 in dom f &
       ||. x1- x .|| < s holds ||. f/.x1 - f/.x .|| < r
     proof
        let x1 be Point of X;
      assume A10: x1 in dom f & ||. x1- x .|| < s;
      set y1= x1-x;
      A11: ||. y1-0.X .|| <s by A10, RLVECT_1:13;
          f/.y1 - f/.(0.X) = f.y1 by A2,RLVECT_1:13
                           .= f.(x1+(-1)*x) by RLVECT_1:16
                           .= f.x1+f.((-1)*x) by VECTSP_1:def 20
                           .= f.x1+(-1)*f.x by LOPBAN_1:def 5
                           .= f.x1-f.x by RLVECT_1:16;
        hence ||. f/.x1 - f/.x .|| < r by A11,A9,A1;
     end;
  end;
  hence f is_continuous_in x by A1,NFCONT_1:7;
 end;
