reserve x,y for set,
  i,j,k,l,m,n for Nat,
  K for Field,
  N for without_zero finite Subset of NAT,
  a,b for Element of K,
  A,B,B1,B2,X,X1,X2 for (Matrix of K),
  A9 for (Matrix of m,n,K),
  B9 for (Matrix of m,k,K);

theorem Th4:
  for K be non empty multMagma, f,g be FinSequence of K,
  a be Element of K holds a * (f^g) = (a*f) ^ (a*g)
proof
  let K be non empty multMagma, f,g be FinSequence of K,a be Element of K;
  set KK=the carrier of K;
  reconsider F=f as Element of (len f)-tuples_on KK by FINSEQ_2:92;
  reconsider G=g as Element of (len g)-tuples_on KK by FINSEQ_2:92;
  reconsider FG=F^G,aFaG=(a*F)^(a*G) as Element of (len f+len g)-tuples_on KK
           by FINSEQ_2:131;
  now
    let i such that
A1: i in Seg (len f+len g);
A2: i in dom FG by A1,FINSEQ_2:124;
    now
      per cases by A2,FINSEQ_1:25;
      suppose
A3:     i in dom f;
A4:     rng f c= KK by RELAT_1:def 19;
        f.i in rng f by A3,FUNCT_1:def 3;
        then reconsider fi=f.i as Element of K by A4;
A5:     dom F=Seg len f by FINSEQ_2:124;
A6:     dom (a*F)=Seg len f by FINSEQ_2:124;
        FG.i=fi by A3,FINSEQ_1:def 7;
        hence (a*FG).i = a*fi by A1,FVSUM_1:51
          .= (a*F).i by A3,A5,FVSUM_1:51
          .= aFaG.i by A3,A5,A6,FINSEQ_1:def 7;
      end;
      suppose
A7:     ex n st n in dom g & i=len f + n;
A8:     rng g c= KK by RELAT_1:def 19;
A9:     dom (a*G)=Seg len g & len (a*F)=len f by CARD_1:def 7,FINSEQ_2:124;
        consider n such that
A10:    n in dom g and
A11:    i=len f + n by A7;
        g.n in rng g by A10,FUNCT_1:def 3;
        then reconsider gn=g.n as Element of K by A8;
A12:    dom G=Seg len g by FINSEQ_2:124;
        FG.i=gn by A10,A11,FINSEQ_1:def 7;
        hence (a*FG).i = a*gn by A1,FVSUM_1:51
          .= (a*G).n by A10,A12,FVSUM_1:51
          .= aFaG.i by A10,A11,A12,A9,FINSEQ_1:def 7;
      end;
    end;
    hence (a*FG).i=aFaG.i;
  end;
  hence thesis by FINSEQ_2:119;
end;
