reserve i,j,m,n,k for Nat,
  x,y for set,
  K for Field,
  a,L for Element of K;

theorem Th4:
  i in Seg n & i<>n implies Line(Jordan_block(L,n),i) = L*Line(1.(K
  ,n),i)+Line(1.(K,n),i+1)
proof
  assume that
A1: i in Seg n and
A2: i<>n;
  reconsider N=n as Element of NAT by ORDINAL1:def 12;
  set J=Jordan_block(L,n);
  set i1=i+1;
  set ONE=1.(K,n);
  set Li=Line(ONE,i);
  set Li1=Line(ONE,i1);
  set LJ=Line(J,i);
A3: width ONE=n by MATRIX_0:24;
A4: Indices ONE=Indices J by MATRIX_0:26;
  reconsider Li,Li1,LJ as Element of N-tuples_on the carrier of K by
MATRIX_0:24;
A5: Indices ONE=[:Seg n,Seg n:] by MATRIX_0:24;
A6: width J=n by MATRIX_0:24;
  now
    let j such that
A7: j in Seg n;
    Li.j=ONE*(i,j) by A3,A7,MATRIX_0:def 7;
    then
A8: (L*Li).j=L*(ONE*(i,j)) by A7,FVSUM_1:51;
A9: [i,j] in [:Seg n,Seg n:] by A1,A7,ZFMISC_1:87;
    i<=n by A1,FINSEQ_1:1;
    then i<n by A2,XXREAL_0:1;
    then 1<=i1 & i1<=n by NAT_1:11,13;
    then i1 in Seg n;
    then
A10: [i1,j] in [:Seg n,Seg n:] by A7,ZFMISC_1:87;
    Li1.j=ONE*(i1,j) by A3,A7,MATRIX_0:def 7;
    then
A11: (L*Li+Li1).j=L*(ONE*(i,j))+ONE*(i1,j) by A7,A8,FVSUM_1:18;
A12: LJ.j=J*(i,j) by A6,A7,MATRIX_0:def 7;
    now
      per cases;
      suppose
A13:    i=j;
        then
A14:    i1>j by NAT_1:13;
        thus LJ.j = L by A5,A4,A9,A12,A13,Def1
          .= L+0.K by RLVECT_1:def 4
          .= L*1_K+0.K
          .= L*(ONE*(i,j))+0.K by A5,A9,A13,MATRIX_1:def 3
          .= (L*Li+Li1).j by A5,A10,A11,A14,MATRIX_1:def 3;
      end;
      suppose
A15:    i1=j;
        then
A16:    i<j by NAT_1:13;
        thus LJ.j = 1_K by A5,A4,A9,A12,A15,Def1
          .= 0.K+1_K by RLVECT_1:def 4
          .= L*0.K+1_K
          .= L*(ONE*(i,j))+1_K by A5,A9,A16,MATRIX_1:def 3
          .= (L*Li+Li1).j by A5,A10,A11,A15,MATRIX_1:def 3;
      end;
      suppose
A17:    i<>j & i1<>j;
        hence LJ.j = 0.K by A5,A4,A9,A12,Def1
          .= 0.K+0.K by RLVECT_1:def 4
          .= L*0.K+0.K
          .= L*(ONE*(i,j))+0.K by A5,A9,A17,MATRIX_1:def 3
          .= (L*Li+Li1).j by A5,A10,A11,A17,MATRIX_1:def 3;
      end;
    end;
    hence (L*Li+Li1).j=LJ.j;
  end;
  hence thesis by FINSEQ_2:119;
end;
