reserve z1,z2,z3,z4,z for Quaternion;

theorem
  z is Real implies z*z3 = [* Rea z*Rea z3,Rea z*Im1 z3,Rea z*Im2 z3,Rea
  z*Im3 z3*]
proof
  assume
A1: z is Real; then
A2: Im3 z = 0 by Lm1;
A3: z * z3 = [*Rea z * Rea z3 - Im1 z * Im1 z3 - Im2 z * Im2 z3 - Im3 z *
Im3 z3, Rea z * Im1 z3 + Im1 z * Rea z3 + Im2 z * Im3 z3 - Im3 z * Im2 z3, Rea
z * Im2 z3 + Im2 z * Rea z3 + Im3 z * Im1 z3 - Im1 z * Im3 z3, Rea z * Im3 z3 +
  Im3 z * Rea z3 + Im1 z * Im2 z3 - Im2 z * Im1 z3 *]
  proof
    reconsider z9 = z * z3 as Quaternion;
    set z1 = [*Rea z * Rea z3 - Im1 z * Im1 z3 - Im2 z * Im2 z3 - Im3 z * Im3
z3, Rea z * Im1 z3 + Im1 z * Rea z3 + Im2 z * Im3 z3 - Im3 z * Im2 z3, Rea z *
Im2 z3 + Im2 z * Rea z3 + Im3 z * Im1 z3 - Im1 z * Im3 z3, Rea z * Im3 z3 + Im3
    z * Rea z3 + Im1 z * Im2 z3 - Im2 z * Im1 z3 *];
A4: Im1 z1 = Rea z * Im1 z3 + Im1 z * Rea z3 + Im2 z * Im3 z3 - Im3 z *
    Im2 z3 by QUATERNI:23
      .= Im1 z9 by QUATERNI:97;
A5: Im2 z1 = Rea z * Im2 z3 + Im2 z * Rea z3 + Im3 z * Im1 z3 - Im1 z *
    Im3 z3 by QUATERNI:23
      .= Im2 z9 by QUATERNI:97;
A6: Im3 z1 = Rea z * Im3 z3 + Im3 z * Rea z3 + Im1 z * Im2 z3 - Im2 z *
    Im1 z3 by QUATERNI:23
      .= Im3 z9 by QUATERNI:97;
    Rea z1 = Rea z * Rea z3 - Im1 z * Im1 z3 - Im2 z * Im2 z3 - Im3 z *
    Im3 z3 by QUATERNI:23
      .= Rea z9 by QUATERNI:97;
    hence thesis by A4,A5,A6,QUATERNI:25;
  end;
  Im1 z = 0 & Im2 z = 0 by A1,Lm1;
  hence thesis by A2,A3;
end;
