reserve Omega, Omega1, Omega2 for non empty set;
reserve Sigma for SigmaField of Omega;
reserve S1 for SigmaField of Omega1;
reserve S2 for SigmaField of Omega2;

theorem Th4:
  for F being Function of Omega,REAL,
  r being Real
  st F is Real-Valued-Random-Variable of Sigma
  holds F"(].-infty,r.[) in Sigma
  proof
    let F be Function of Omega,REAL;
    let r be Real;
    assume F is Real-Valued-Random-Variable of Sigma; then
    F is ([#]Sigma)-measurable; then
    A2:([#]Sigma) /\ (less_dom (F,r)) in Sigma by MESFUNC6:12;
    for z be object holds
    z in F"(].-infty,r.[) iff z in ([#]Sigma) /\ (less_dom (F,r))
    proof
      let z be object;
      hereby assume A3: z in F"(].-infty,r.[);
        then
        A4: z in dom F & F.z in ].-infty,r.[ by FUNCT_1:def 7;
        then
        F.z in {p where p is Real : -infty<p & p<r } by RCOMP_1:def 2;
        then consider w be Real such that
        A5: F.z = w & -infty < w & w < r;
        z in less_dom (F,r) by A4,A5,MESFUNC1:def 11;
        hence z in ([#]Sigma) /\ (less_dom (F,r)) by A3,XBOOLE_0:def 4;
      end;
      assume z in ([#]Sigma) /\ (less_dom (F,r)); then
      A6: z in ([#]Sigma) & z in (less_dom (F,r)) by XBOOLE_0:def 4;
      then
      A7: z in dom F & F.z < r by MESFUNC1:def 11;
      -infty < F.z & F.z < r by XXREAL_0:12,FUNCT_2:5,MESFUNC1:def 11,A6;
      then
      F.z in {p where p is Real : -infty<p & p<r }; then
      F.z in ].-infty,r.[ by RCOMP_1:def 2;
      hence z in F"(].-infty,r.[) by A7, FUNCT_1:def 7;
    end;
    hence thesis by A2,TARSKI:2;
  end;
