reserve L for Ortholattice,
  a, b, c for Element of L;

theorem Th4:
  for L being involutive Lattice-like non empty OrthoLattStr
  holds L is de_Morgan iff for a,b being Element of L st a [= b holds b` [= a`
proof
  let L be involutive Lattice-like non empty OrthoLattStr;
  thus L is de_Morgan implies for a,b being Element of L st a [= b holds b` [=
  a`
  proof
    assume
A1: L is de_Morgan;
    let a,b be Element of L;
    assume a [= b;
    then a` = (a"/\"b)` by LATTICES:4
      .= (a`"\/"b`)`` by A1
      .= b`"\/"a` by ROBBINS3:def 6;
    then a` "/\" b` = b` by LATTICES:def 9;
    hence thesis by LATTICES:4;
  end;
  assume
A2: for a,b being Element of L st a [= b holds b` [= a`;
  let x,y be Element of L;
  (x` "\/" y`)` [= y`` by A2,LATTICES:5;
  then
A3: (x` "\/" y`)` [= y by ROBBINS3:def 6;
  x` [= (x "/\" y)` & y` [= (x "/\" y)` by A2,LATTICES:6;
  then x` "\/" y` [= (x "/\" y)` by FILTER_0:6;
  then (x "/\" y)`` [= (x` "\/" y`)` by A2;
  then
A4: x "/\" y [= (x` "\/" y`)` by ROBBINS3:def 6;
  (x` "\/" y`)` [= x`` by A2,LATTICES:5;
  then (x` "\/" y`)` [= x by ROBBINS3:def 6;
  then (x` "\/" y`)` [= x "/\" y by A3,FILTER_0:7;
  hence thesis by A4,LATTICES:8;
end;
