reserve m, n for Nat,
  x for set,
  i for Instruction of SCM+FSA,
  I for Program of SCM+FSA,
  a for Int-Location,
  f for FinSeq-Location,
  l, l1 for Nat,
  s,s1,s2 for State of SCM+FSA,
  P,P1,P2 for Instruction-Sequence of SCM+FSA;

theorem
  for I being parahalting really-closed Program of SCM+FSA
   holds not f in UsedI*Loc I implies (IExec(I,P,s)).f = s.f
proof
  let I be parahalting really-closed Program of SCM+FSA;
  assume
A1: not f in UsedI*Loc I;
A2: I c= P+*I by FUNCT_4:25;
A3:  Initialize((intloc 0).-->1) c= s +* Initialize((intloc 0).-->1)
   by FUNCT_4:25;
  then P+*I halts_on s +* Initialize((intloc 0).-->1) by Th2,A2;
  then consider n such that
A4: Result(P+*I,s +* Initialize((intloc 0).-->1))
      = Comput(P+*I,s +* Initialize((intloc 0).-->1),n) and
  CurInstr(P+*I,Result(P+*I,s +* Initialize((intloc 0).-->1)))
   = halt SCM+FSA by EXTPRO_1:def 9;
A5: dom Initialize((intloc 0).-->1) =
      dom((intloc 0).-->1) \/ dom Start-At(0,SCM+FSA) by FUNCT_4:def 1;
A6: not f in dom Start-At(0,SCM+FSA) by SCMFSA_2:103;
    f <> intloc 0 by SCMFSA_2:58;
    then not f in {intloc 0} by TARSKI:def 1;
    then not f in dom((intloc 0).-->1);
    then
A7: not f in dom Initialize((intloc 0).-->1) by A5,A6,XBOOLE_0:def 3;
  for m st m < n
   holds IC Comput(P+*I,s+*Initialize((intloc 0).-->1),m) in dom I
   proof
     IC(s+*Initialize((intloc 0).-->1)) = 0 by A3,MEMSTR_0:47;
     then IC(s+*Initialize((intloc 0).-->1)) in dom I by AFINSQ_1:65;
    hence thesis by A2,AMISTD_1:21;
   end;
  hence (IExec(I,P,s)).f = (s +* Initialize((intloc 0).-->1)).f
   by A1,A4,FUNCT_4:25,SF_MASTR:63
    .= s.f by A7,FUNCT_4:11;
end;
