reserve s for State of SCM+FSA,
  a, c for read-write Int-Location,
  aa, bb, cc,
  dd, x for Int-Location,
  f for FinSeq-Location,
  I, J for MacroInstruction of SCM+FSA,
  Ig for good MacroInstruction of SCM+FSA,
  i, k for Nat,
  p for Instruction-Sequence of SCM+FSA;

theorem Th3:
  aa <> bb implies cc := bb does not refer aa
proof
  assume
A1: aa <> bb;
  now
    let e be Int-Location;
    let l be Nat;
    let f be FinSeq-Location;
    thus e := aa <> cc := bb by A1,SF_MASTR:1;
A2: InsCode (cc := bb) = 1 by SCMFSA_2:18;
    hence AddTo(e,aa) <> cc := bb by SCMFSA_2:19;
    thus SubFrom(e,aa) <> cc := bb by A2,SCMFSA_2:20;
    thus MultBy(e,aa) <> cc := bb by A2,SCMFSA_2:21;
    thus Divide(aa,e) <> cc := bb & Divide(e,aa) <> cc := bb by A2,SCMFSA_2:22;
    thus aa =0_goto l <> cc := bb;
    thus aa >0_goto l <> cc := bb;
    thus e :=(f,aa) <> cc := bb by A2,SCMFSA_2:26;
    thus (f,e):= aa <> cc := bb & (f,aa):= e <> cc := bb by A2,SCMFSA_2:27;
    thus f :=<0,...,0> aa <> cc := bb by A2,SCMFSA_2:29;
  end;
  hence thesis;
end;
