reserve A,B,C for Ordinal,
        o for object,
        x,y,z,t,r,l for Surreal,
        X,Y for set;

theorem Th4:
  for S be c=-monotone Function-yielding Sequence st
    for B st B in dom S
      ex SB be ManySortedSet of Day B st S.B = SB &
         for o st o in Day B holds
           SB.o = [union rng (S|B).:R_o, union rng(S|B).:L_o]
    holds
  for A st A in dom S holds No_opposite_op A = S.A
proof
  deffunc D(Ordinal) = Day $1;
  deffunc H(object,c=-monotone Function-yielding Sequence) =
         [(union rng $2).:R_$1, (union rng $2).:L_$1];
  let S1 be c=-monotone Function-yielding Sequence such that
  A1:for B be Ordinal st B in dom S1
       ex SB be ManySortedSet of D(B) st S1.B = SB &
         for x be object st x in D(B) holds SB.x = H(x,S1|B);
  let A be Ordinal such that A2: A in dom S1;
  A3:succ A c= dom S1 by A2,ORDINAL1:21;
  consider S2 be c=-monotone Function-yielding Sequence such that
  A4:dom S2 = succ A & S2.A = No_opposite_op A &
      for B be Ordinal st B in succ A
         ex SB be ManySortedSet of D(B) st S2.B = SB &
           for x be object st x in D(B) holds
             SB.x = H(x,S2|B) by Def2;
  A5: for B be Ordinal st B in succ A
    ex SB be ManySortedSet of D(B) st S1.B = SB &
        for x be object st x in D(B) holds SB.x = H(x,S1|B) by A1,A3;
  A6: for B be Ordinal st B in succ A
    ex SB be ManySortedSet of D(B) st S2.B = SB &
      for x be object st x in D(B) holds SB.x = H(x,S2|B) by A4;
  A7: succ A c= dom S1 & succ A c= dom S2 by A2,ORDINAL1:21,A4;
  A8: S1|succ A = S2|succ A from MonoFvSUniq(A7,A5,A6);
  A in succ A by ORDINAL1:8;
  hence thesis by A4,A8,FUNCT_1:49;
end;
