reserve a,b,c for set;

theorem Th4:
  for X being set, F being Subset-Family of X st {} in F & (for A,B
being set st A in F & B in F holds A \/ B in F) & (for G being Subset-Family of
X st G c= F holds Intersect G in F) for T being TopStruct st the carrier of T =
  X & the topology of T = COMPLEMENT F holds T is TopSpace & for A being Subset
  of T holds A is closed iff A in F
proof
  let X be set;
  let F be Subset-Family of X;
  assume
A1: {} in F;
  set O = COMPLEMENT F;
  assume
A2: for A,B being set st A in F & B in F holds A \/ B in F;
  assume
A3: for G being Subset-Family of X st G c= F holds Intersect G in F;
  let T be TopStruct such that
A4: the carrier of T = X and
A5: the topology of T = O;
  T is TopSpace-like
  proof
    ({}T)` in O by A1,A4,SETFAM_1:35;
    hence the carrier of T in the topology of T by A5;
    hereby
      let a be Subset-Family of T;
      assume a c= the topology of T;
      then COMPLEMENT a c= F by A4,A5,SETFAM_1:37;
      then Intersect COMPLEMENT a in F by A3,A4;
      then (union a)` in F by YELLOW_8:6;
      hence union a in the topology of T by A4,A5,SETFAM_1:def 7;
    end;
    let a,b be Subset of T;
    assume that
A6: a in the topology of T and
A7: b in the topology of T;
A8: b` in F by A7,A4,A5,SETFAM_1:def 7;
    a` in F by A6,A4,A5,SETFAM_1:def 7;
    then a` \/ b` in F by A8,A2;
    then (a /\ b)` in F by XBOOLE_1:54;
    hence thesis by A4,A5,SETFAM_1:def 7;
  end;
  hence T is TopSpace;
  let A be Subset of T;
  A is closed iff A` is open;
  then A is closed iff A` in O by A5;
  hence thesis by A4,SETFAM_1:35;
end;
