reserve a for set;
reserve p,p1,p2,q,q1,q2 for Point of TOP-REAL 2;
reserve h1,h2 for FinSequence of TOP-REAL 2;

theorem Th4:
  for P being non empty Subset of TOP-REAL 2 st P is
  being_simple_closed_curve ex p1,p2 st p1 <> p2 & p1 in P & p2 in P
proof
  reconsider RS = R^2-unit_square as non empty Subset of TOP-REAL 2;
  let P be non empty Subset of TOP-REAL 2;
A1: p00`1 = 0 by EUCLID:52;
A2: [#]((TOP-REAL 2)|P) c= [#] (TOP-REAL 2) by PRE_TOPC:def 4;
A3: p11`1 = 1 by EUCLID:52;
  assume P is being_simple_closed_curve;
  then consider
  f being Function of (TOP-REAL 2)|R^2-unit_square, (TOP-REAL 2)|P
  such that
A4: f is being_homeomorphism;
A5: rng f = [#]((TOP-REAL 2)|P) by A4
    .= P by PRE_TOPC:def 5;
  reconsider f as Function of (TOP-REAL 2)|RS, (TOP-REAL 2)|P;
A6: dom f = [#]((TOP-REAL 2)|RS) by FUNCT_2:def 1
    .= R^2-unit_square by PRE_TOPC:def 5;
  set p1 = f.p00, p2 = f.(p11);
  p00`2 = 0 by EUCLID:52;
  then
A7: p00 in dom f by A1,A6,TOPREAL1:14;
  then
A8: p1 in rng f by FUNCT_1:def 3;
  p11`2 = 1 by EUCLID:52;
  then
A9: p11 in dom f by A3,A6,TOPREAL1:14;
  then
A10: p2 in rng f by FUNCT_1:def 3;
  reconsider p1, p2 as Point of TOP-REAL 2 by A2,A8,A10;
  take p1, p2;
  f is one-to-one by A4;
  hence p1 <> p2 by A1,A3,A7,A9,FUNCT_1:def 4;
  thus thesis by A5,A7,A9,FUNCT_1:def 3;
end;
