
theorem Th4:
  for L1, L2 being complete LATTICE, T1 being Scott TopAugmentation
  of L1, T2 being Scott TopAugmentation of L2, h being Function of L1, L2, H
  being Function of T1, T2 st h = H & h is isomorphic holds H is
  being_homeomorphism
proof
  let L1, L2 be complete LATTICE, T1 be Scott TopAugmentation of L1, T2 be
  Scott TopAugmentation of L2, h be Function of L1, L2, H be Function of T1, T2
  such that
A1: h = H and
A2: h is isomorphic;
A3: the RelStr of L2 = the RelStr of T2 by YELLOW_9:def 4;
A4: the RelStr of L1 = the RelStr of T1 by YELLOW_9:def 4;
  then reconsider H9 = h" as Function of T2, T1 by A3;
  consider g being Function of L2,L1 such that
A5: g = h";
  g = (h qua Function)" by A2,A5,TOPS_2:def 4;
  then g is isomorphic by A2,WAYBEL_0:68;
  then reconsider h2 = h" as sups-preserving Function of L2,L1 by A5,
WAYBEL13:20;
A6: rng H = [#]T2 by A1,A2,A3,WAYBEL_0:66;
A7: for x being object st x in dom H9 holds H9.x = H".x
  proof
    let x be object;
    assume x in dom H9;
A8: H is onto by A6,FUNCT_2:def 3;
    thus H9.x = (h qua Function)".x by A2,TOPS_2:def 4
      .= H".x by A1,A2,A8,TOPS_2:def 4;
  end;
  h2 is directed-sups-preserving;
  then
A9: H9 is directed-sups-preserving by A4,A3,WAYBEL21:6;
  dom (H") = the carrier of T2 by FUNCT_2:def 1
    .= dom H9 by FUNCT_2:def 1;
  then
A10: H" = H9 by A7,FUNCT_1:2;
  reconsider h1 = h as sups-preserving Function of L1,L2 by A2,WAYBEL13:20;
  h1 is directed-sups-preserving;
  then
A11: H is directed-sups-preserving by A1,A4,A3,WAYBEL21:6;
  dom H = [#]T1 by FUNCT_2:def 1;
  hence thesis by A1,A2,A11,A9,A6,A10;
end;
