reserve H for ZF-formula,
  M,E for non empty set,
  e for Element of E,
  m,m0,m3, m4 for Element of M,
  v,v1,v2 for Function of VAR,M,
  f,f1 for Function of VAR,E,
  g for Function,
  u,u1,u2 for set,
  x,y for Variable,
  i,n for Element of NAT,
  X for set;
reserve W for Universe,
  w for Element of W,
  Y for Subclass of W,
  a,a1,b,c for Ordinal of W,
  L for DOMAIN-Sequence of W;

theorem Th4:
  Section(H,v)= {m : {[{},m]} \/ (v*decode)|((code Free H)\{{}}) in
  Diagram(H,M)}
proof
  set S=Section(H,v);
  set D={m:{[{},m]}\/(v*decode)|((code Free H)\{{}}) in Diagram(H,M)};
  now
    per cases;
    suppose
A1:   x.0 in Free H;
      then
A2:   S={m: M,v/(x.0,m) |= H} by Def1;
A3:   D c= S
      proof
        let u be object;
        assume u in D;
        then consider m such that
A4:     m=u and
A5:     {[{},m]}\/(v*decode)|((code Free H)\{{}}) in Diagram(H,M);
        (v/(x.0,m)*decode)|code Free H in Diagram(H,M) by A1,A5,Lm5;
        then
        ex v1 st (v/(x.0,m)*decode)|code Free H=(v1*decode)|code Free H &
        v1 in St(H,M) by ZF_FUND1:def 5;
        then v/(x.0,m) in St(H,M) by ZF_FUND1:36;
        then M,v/(x.0,m) |= H by ZF_MODEL:def 4;
        hence thesis by A2,A4;
      end;
      S c= D
      proof
        let u be object;
        assume u in S;
        then consider m such that
A6:     m=u and
A7:     M,v/(x.0,m) |= H by A2;
        v/(x.0,m) in St(H,M) by A7,ZF_MODEL:def 4;
        then (v/(x.0,m)*decode)|code Free H in Diagram(H,M) by ZF_FUND1:def 5;
        then {[{},m]}\/(v*decode)|((code Free H)\{{}}) in Diagram(H,M) by A1
,Lm5;
        hence thesis by A6;
      end;
      hence thesis by A3;
    end;
    suppose
A8:   not x.0 in Free H;
      now
        set u = the Element of D;
        assume D<>{};
        then u in D;
        then consider m such that
        m=u and
A9:     {[{},m]}\/(v*decode)|((code Free H)\{{}}) in Diagram(H,M);
        consider v2 such that
A10:    ({[{},m]}\/(v*decode)|((code Free H)\{{}})) =(v2*decode)|code
        Free H and
        v2 in St(H,M) by A9,ZF_FUND1:def 5;
        reconsider w={[{},m]}\/(v*decode)|((code Free H)\{{}}) as Function by
A10;
        [{},m]in{[{},m]} by TARSKI:def 1;
        then [{},m] in w by XBOOLE_0:def 3;
        then {} in dom w by FUNCT_1:1;
        then {} in dom(v2*decode)/\(code Free H) by A10,RELAT_1:61;
        then {} in code Free H by XBOOLE_0:def 4;
        then ex y st y in Free H & {}=x".y by ZF_FUND1:33;
        hence contradiction by A8,ZF_FUND1:def 3;
      end;
      hence thesis by A8,Def1;
    end;
  end;
  hence thesis;
end;
