
theorem GauF04:
for a,b be Real, f be Function of REAL,REAL st
(b <> 0 & for x be Real holds f.x= exp_R(-(x-a)^2/(2*b^2)))
holds
f is FuzzySet of REAL
proof
 let a,b be Real;
 let f be Function of REAL,REAL;
 assume A1:b<>0;
 assume A2: for x be Real holds f.x= exp_R(-(x-a)^2/(2*b^2));
 rng f c= [.0,1.]
 proof
  let z be object;
  assume z in rng f; then
  consider x be object such that
  B2: x in REAL and
  B3: f . x = z by FUNCT_2:11;
  reconsider x as Real by B2;
  B4:z=exp_R(-(x-a)^2/(2*b^2)) by B3,A2;
  B5:exp_R(-(x-a)^2/(2*b^2)) <= 1
  proof
  per cases;
   suppose x=a; then
    exp_R(-(x-a)^2/(2*b^2)) = 1 by SIN_COS:51;
    hence thesis;
   end;
   suppose x<>a; then
    (x-a)<>0; then
    (x-a)^2>0 & b^2 >0 by SQUARE_1:12,A1; then
    exp_R. (-(x-a)^2/(2*b^2)) <=1 by SIN_COS:53;
    hence thesis by SIN_COS:def 23;
   end;
  end;
  0 <= exp_R(-(x-a)^2/(2*b^2)) & exp_R(-(x-a)^2/(2*b^2)) <= 1
    by B5,SIN_COS:55;
  hence thesis by B4;
 end; then
 f is [.0,1.] -valued;
 hence thesis;
end;
