reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem Th50:
  1 <= j & j < width G implies LSeg(1/2*(G*(len G,j)+G*(len G,j+1)
) + |[1,0]|,G*(len G,j) + |[1,0]|) c= Int cell(G,len G,j) \/ { G*(len G,j) + |[
  1,0]| }
proof
  assume that
A1: 1 <= j and
A2: j < width G;
  let x be object;
  assume
A3: x in LSeg(1/2*(G*(len G,j)+G*(len G,j+1))+|[1,0]|,G* (len G,j) + |[1 ,0]|);
  then reconsider p = x as Point of TOP-REAL 2;
  consider r such that
A4: p = (1-r)*(1/2*(G*(len G,j)+G*(len G,j+1))+|[1,0]|)+ r*(G*(len G,j)
  + |[1,0]|) and
A5: 0<=r and
A6: r<=1 by A3;
  now
    per cases by A6,XXREAL_0:1;
    case
      r = 1;
      then p = 0.TOP-REAL 2 + 1*(G*(len G,j) + |[1,0]|) by A4,RLVECT_1:10
        .= 1*(G*(len G,j) + |[1,0]|) by RLVECT_1:4
        .= (G*(len G,j) + |[1,0]|) by RLVECT_1:def 8;
      hence p in { G*(len G,j) + |[1,0]| } by TARSKI:def 1;
    end;
    case
A7:   r < 1;
      set r3 = (1-r)*(1/2);
      1 - r > 0 by A7,XREAL_1:50;
      then
A8:   r3 > (1/2)*0 by XREAL_1:68;
      set r2 = G*(len G,1)`1, s1 = G*(1,j)`2, s2 = G*(1,j+1)`2;
A9:   r3*(s1+s1)+r*s1 = s1;
A10:  j+1 <= width G by A2,NAT_1:13;
      0 <> len G by MATRIX_0:def 10;
      then
A11:  1 <= len G by NAT_1:14;
A12:  G*(len G,j) = |[G*(len G,j)`1,G*(len G,j)`2]| by EUCLID:53
        .= |[r2,G*(len G,j)`2]| by A1,A2,A11,GOBOARD5:2
        .= |[r2,s1]| by A1,A2,A11,GOBOARD5:1;
A13:  1 <= j+1 by A1,NAT_1:13;
      j < j+1 by XREAL_1:29;
      then
A14:  s1 < s2 by A1,A10,A11,GOBOARD5:4;
      then s1+s2 < s2+s2 by XREAL_1:6;
      then
A15:  r3*(s1+s2) < r3*(s2+s2) by A8,XREAL_1:68;
      s1+s1 < s1+s2 by A14,XREAL_1:6;
      then r3*(s1+s1) < r3*(s1+s2) by A8,XREAL_1:68;
      then
A16:  r2 < r2+1 & s1 < r3*(s1+s2)+r*s1 by A9,XREAL_1:6,29;
A17:  Int cell(G,len G,j) = { |[r9,s9]| : G*(len G,1)`1 < r9 & G*(1,j)`2
      < s9 & s9 < G*(1,j+1)`2 } by A1,A2,Th23;
A18:  G*(len G,j+1) = |[G*(len G,j+1)`1,G*(len G,j+1)`2]| by EUCLID:53
        .= |[r2,G*(len G,j+1)`2]| by A13,A10,A11,GOBOARD5:2
        .= |[r2,s2]| by A13,A10,A11,GOBOARD5:1;
A19:  r3*(s2+s2)+r*s2 = s2;
      r*s1 <= r*s2 by A5,A14,XREAL_1:64;
      then
A20:  r3*(s1+s2)+r*s1 < s2 by A15,A19,XREAL_1:8;
      p = (1-r)*(1/2*(G*(len G,j)+G*(len G,j+1)))+(1-r)*|[1,0]| +r*(G*(
      len G,j) + |[1,0]|) by A4,RLVECT_1:def 5
        .= r3*(G*(len G,j)+G*(len G,j+1))+(1-r)*|[1,0]|+r*(G* (len G,j) + |[
      1,0]|) by RLVECT_1:def 7
        .= r3*(G*(len G,j)+G*(len G,j+1))+|[(1-r)*1,(1-r)*0]|+ r*(G*(len G,j
      ) + |[1,0]|) by EUCLID:58
        .= r3*|[r2+r2,s1+s2]|+|[1-r,0]|+r*(|[r2,s1]| + |[1,0]|) by A18,A12,
EUCLID:56
        .= r3*|[r2+r2,s1+s2]|+|[1-r,0]|+(r*|[r2,s1]| + r*|[1,0]|) by
RLVECT_1:def 5
        .= r3*|[r2+r2,s1+s2]|+|[1-r,0]|+(|[r*r2,r*s1]| + r*|[1,0]|) by
EUCLID:58
        .= r3*|[r2+r2,s1+s2]|+|[1-r,0]|+(|[r*r2,r*s1]| + |[r*1,r*0]|) by
EUCLID:58
        .= r3*|[r2+r2,s1+s2]|+|[1-r,0]|+|[r*r2+r,r*s1+0]| by EUCLID:56
        .= |[r3*(r2+r2),r3*(s1+s2)]|+|[1-r,0]|+|[r*r2+r,r*s1+0]| by EUCLID:58
        .= |[r3*(r2+r2)+(1-r),r3*(s1+s2)+0]|+|[r*r2+r,r*s1+0]| by EUCLID:56
        .= |[r3*(r2+r2)+(1-r)+(r*r2+r),r3*(s1+s2)+r*s1]| by EUCLID:56;
      hence p in Int cell(G,len G,j) by A16,A20,A17;
    end;
  end;
  hence thesis by XBOOLE_0:def 3;
end;
