reserve a,b,c,k,m,n for Nat;
reserve i,j,x,y for Integer;
reserve p,q for Prime;
reserve r,s for Real;

theorem Th50:
  for k being positive Nat holds Sum powersFS(-k,3,2*k-1) = 0
  proof
    let k be positive Nat;
    defpred P[non zero Nat] means Sum powersFS(-$1,3,2*$1-1) = 0;
A1: P[1]
    proof
      set f = powersFS(-1,3,2*1-1);
      len f = 1 & f.1 = (-1+1) to_power 3 by Def7;
      then f = <*0*> by FINSEQ_1:40;
      hence Sum f = 0;
    end;
A2: for n being non zero Nat st P[n] holds P[n+1]
    proof
      let n be non zero Nat such that
A3:   P[n];
      set f = powersFS(-(n+1),3,2*(n+1)-1);
      set g = powersFS(-n,3,2*n-1);
      set a = (-n) to_power 3;
      set b = n to_power 3;
A4:   Sum(<*a*>^g) = a + Sum g by RVSUM_1:76;
A5:   (-n) to_power 3 = (-n)*(-n)*(-n) & n to_power 3 = n*n*n
      by POLYEQ_5:2;
      f = <*a*> ^ g ^ <*b*> by Th48;
      hence Sum f = a + b by A3,A4,RVSUM_1:74
      .= 0 by A5;
    end;
    for n being non zero Nat holds P[n] from NAT_1:sch 10(A1,A2);
    hence thesis;
  end;
