reserve a,b,c,d for Ordinal;
reserve l for non empty limit_ordinal Ordinal;
reserve u for Element of l;
reserve A for non empty Ordinal;
reserve e for Element of A;
reserve X,Y,x,y,z for set;
reserve n,m for Nat;
reserve f for Ordinal-Sequence;
reserve U,W for Universe;
reserve F,phi for normal Ordinal-Sequence of W;
reserve g for Ordinal-Sequence-valued Sequence;

theorem Th50:
  dom g <> {} & (for c st c in dom g holds b is_a_fixpoint_of g.c) implies
  ex a st a in dom criticals g & b = (criticals g).a
  proof
    reconsider X = {a where a is Element of dom(g.0): a in dom(g.0) &
    for f st f in rng g holds a is_a_fixpoint_of f} as ordinal-membered set
    by Th46;
    assume that
A1: dom g <> {} and
A2: for c st c in dom g holds b is_a_fixpoint_of g.c;
    b is_a_fixpoint_of g.0 by A2,A1,ORDINAL3:8; then
A3: b in dom(g.0);
    now
      let f; assume f in rng g;
      then ex x being object st x in dom g & f = g.x by FUNCT_1:def 3;
      hence b is_a_fixpoint_of f by A2;
    end; then
    b in X by A3; then
    b in rng criticals g by Th19; then
    ex x being object st x in dom criticals g & b = (criticals g).x
by FUNCT_1:def 3;
    hence thesis;
  end;
