
theorem
  for A being finite Ordinal-Sequence, b being Ordinal, n being Nat
  holds b -leading_coeff (A /^ n) = (b -leading_coeff A) /^ n
proof
  let A be finite Ordinal-Sequence, b be Ordinal, n be Nat;
  A1: dom(b -leading_coeff (A /^ n)) = len(A /^ n) by Def3
    .= len A -' n by AFINSQ_2:def 2
    .= len(b -leading_coeff A) -' n by Def3
    .= dom((b -leading_coeff A) /^ n) by AFINSQ_2:def 2;
  now
    let k be Nat;
    assume A2: k in dom(b -leading_coeff (A /^ n));
    then A3: k in dom(A /^ n) by Def3;
    A4: b-leading_coeff(A.(k+n)) = (b-leading_coeff A).(k+n)
    proof
      per cases;
      suppose k+n in dom A;
        hence thesis by Def3;
      end;
      suppose A5: not k+n in dom A;
        then A.(k+n) = {} by FUNCT_1:def 2;
        then A6: b-leading_coeff(A.(k+n)) = {} by ORDINAL3:70;
        not k+n in dom(b-leading_coeff A) by A5, Def3;
        hence thesis by A6, FUNCT_1:def 2;
      end;
    end;
    thus (b -leading_coeff (A /^ n)).k = b-leading_coeff((A/^n).k) by A3, Def3
      .= b-leading_coeff(A.(k+n)) by A3, AFINSQ_2:def 2
      .= ((b -leading_coeff A) /^ n).k by A1, A2, A4, AFINSQ_2:def 2;
  end;
  hence thesis by A1, AFINSQ_1:8;
end;
