reserve p, q, x, y for Real,
  n for Nat;
reserve X for non empty TopSpace,
  a, b, c, d, e, f for Point of X,
  T for non empty pathwise_connected TopSpace,
  a1, b1, c1, d1, e1, f1 for Point of T;
reserve x0, x1 for Point of X,
  P, Q for Path of x0,x1,
  y0, y1 for Point of T,
  R, V for Path of y0,y1;

theorem Th50:
  x0,x1 are_connected implies pi_1-iso(P) is Homomorphism of pi_1(
  X,x1), pi_1(X,x0)
proof
  set f = pi_1-iso(P);
  assume
A1: x0,x1 are_connected;
  now
    let x, y be Element of pi_1(X,x1);
    consider A being Loop of x1 such that
A2: x = Class(EqRel(X,x1),A) by Th47;
    consider B being Loop of x1 such that
A3: y = Class(EqRel(X,x1),B) by Th47;
    consider D being Loop of x0 such that
A4: f.y = Class(EqRel(X,x0),D) by Th47;
    f.y = Class(EqRel(X,x0),P+B+-P) by A1,A3,Def6;
    then
A5: D,P+B+-P are_homotopic by A4,Th46;
A6: P+(A+B)+-P,P+A+-P+(P+B+-P) are_homotopic by A1,Th43;
    consider C being Loop of x0 such that
A7: f.x = Class(EqRel(X,x0),C) by Th47;
    f.x = Class(EqRel(X,x0),P+A+-P) by A1,A2,Def6;
    then C,P+A+-P are_homotopic by A7,Th46;
    then C+D,P+A+-P+(P+B+-P) are_homotopic by A5,BORSUK_6:75;
    then
A8: P+(A+B)+-P,C+D are_homotopic by A6,BORSUK_6:79;
    thus f.(x*y) = f.Class(EqRel(X,x1),A+B) by A2,A3,Lm4
      .= Class(EqRel(X,x0),P+(A+B)+-P) by A1,Def6
      .= Class(EqRel(X,x0),C+D) by A8,Th46
      .= f.x * f.y by A7,A4,Lm4;
  end;
  hence thesis by GROUP_6:def 6;
end;
