reserve x,y for set,
  i for Nat;
reserve V for non empty CLSStruct,
  u,v,v1,v2,v3 for VECTOR of V,
  A for Subset of V,
  l, l1, l2 for C_Linear_Combination of A,
  x,y,y1,y2 for set,
  a,b for Complex,
  F for FinSequence of the carrier of V,
  f for Function of the carrier of V, COMPLEX;
reserve K,L,L1,L2,L3 for C_Linear_Combination of V;
reserve e,e1,e2 for Element of C_LinComb V;

theorem Th51:
  for V being vector-distributive scalar-distributive scalar-associative
  scalar-unital non empty CLSStruct, M be
  Subset of V holds 1r*M = M
proof
  let V be vector-distributive scalar-distributive scalar-associative
  scalar-unital non empty CLSStruct;
  let M be Subset of V;
  for v being Element of V st v in M holds v in 1r*M
  proof
    let v be Element of V;
A1: v = 1r*v by CLVECT_1:def 5;
    assume v in M;
    hence thesis by A1;
  end;
  then
A2: M c= 1r*M;
  for v being Element of V st v in 1r*M holds v in M
  proof
    let v be Element of V;
    assume v in 1r*M;
    then ex x be Element of V st v = 1r*x & x in M;
    hence thesis by CLVECT_1:def 5;
  end;
  then 1r*M c= M;
  hence thesis by A2,XBOOLE_0:def 10;
end;
