 reserve Rseq, Rseq1, Rseq2 for Function of [:NAT,NAT:],REAL;

theorem SH7:
  for X being non empty set, fs being FinSequence of X,
      fss being Subset of fs
  holds Seq fss,fss are_fiberwise_equipotent
proof
   let X be non empty set, fs be FinSequence of X, fss be Subset of fs;
   dom fss c= dom fs by RELAT_1:11; then
A0:dom fss c= Seg len fs by FINSEQ_1:def 3; then
A1:fss is FinSubsequence by FINSEQ_1:def 12; then
A2:Seq fss = fss*Sgm(dom fss) by FINSEQ_1:def 15;
A3:rng Sgm(dom fss) = dom fss by A1,FINSEQ_1:50; then
A4:dom Sgm(dom fss) = dom Seq fss by A2,RELAT_1:27;
a0: dom fss is included_in_Seg by A0,FINSEQ_1:def 13;
   now let x1,x2 be object;
    assume A5: x1 in dom Sgm(dom fss) & x2 in dom Sgm(dom fss)
      & Sgm(dom fss).x1 = Sgm(dom fss).x2;
    reconsider i1 = x1, i2 = x2 as Nat by A5;
    reconsider k1 = Sgm(dom fss).i1, k2 = Sgm(dom fss).i2 as Nat;
A6: 1 <= i1 & 1<= i2 & i1 <= len Sgm(dom fss) & i2 <=len Sgm(dom fss)
      by A5,FINSEQ_3:25;
    now assume i1 <> i2; then
     i1 < i2 or i1 > i2 by XXREAL_0:1;
     hence contradiction by A5,A6,a0,FINSEQ_1:def 14;
    end;
    hence x1 = x2;
   end;
   hence thesis by A2,A3,A4,CLASSES1:77,FUNCT_1:def 4;
end;
