reserve x,y,X,Y for set,
  k,l,n for Nat,
  i,i1,i2,i3,j for Integer,
  G for Group,
  a,b,c,d for Element of G,
  A,B,C for Subset of G,
  H,H1,H2, H3 for Subgroup of G,
  h for Element of H,
  F,F1,F2 for FinSequence of the carrier of G,
  I,I1,I2 for FinSequence of INT;

theorem Th51:
  H1 * H2 = H2 * H1 implies the carrier of H1 "\/" H2 = H1 * H2
proof
  assume H1 * H2 = H2 * H1;
  then consider H being strict Subgroup of G such that
A1: the carrier of H = carr H1 * carr H2 by GROUP_2:78;
  now
    reconsider p = 1 as Integer;
    let a;
    assume a in H;
    then a in carr H1 * carr H2 by A1,STRUCT_0:def 5;
    then consider b,c such that
A2: a = b * c and
A3: b in carr H1 & c in carr H2;
    b in carr H1 \/ carr H2 & c in carr H1 \/ carr H2 by A3,XBOOLE_0:def 3;
    then
A4: rng<* b,c *> = {b,c} & {b,c} c= carr H1 \/ carr H2 by FINSEQ_2:127
,ZFMISC_1:32;
A5: len<* b,c *> = 2 & len<* @p,@p *> = 2 by FINSEQ_1:44;
    a = Product<* b *> * c by A2,FINSOP_1:11
      .= Product<* b *> * Product<* c *> by FINSOP_1:11
      .= Product(<* b *> ^ <* c *>) by FINSOP_1:5
      .= Product<* b,c *> by FINSEQ_1:def 9
      .= Product<* b |^ p, c *> by GROUP_1:26
      .= Product<* b |^ p, c |^ p *> by GROUP_1:26
      .= Product(<* b,c *> |^ <* @p,@p *>) by Th23;
    hence a in H1 "\/" H2 by A5,A4,Th28;
  end;
  then
A6: H is Subgroup of H1 "\/" H2 by GROUP_2:58;
  carr H1 \/ carr H2 c= carr H1 * carr H2
  proof
    let x be object;
    assume
A7: x in carr H1 \/ carr H2;
    then reconsider a = x as Element of G;
    now
      per cases by A7,XBOOLE_0:def 3;
      suppose
A8:     x in carr H1;
        1_G in H2 by GROUP_2:46;
        then
A9:     1_G in carr H2 by STRUCT_0:def 5;
        a * 1_G = a by GROUP_1:def 4;
        hence thesis by A8,A9;
      end;
      suppose
A10:    x in carr H2;
        1_G in H1 by GROUP_2:46;
        then
A11:    1_G in carr H1 by STRUCT_0:def 5;
        1_G * a = a by GROUP_1:def 4;
        hence thesis by A10,A11;
      end;
    end;
    hence thesis;
  end;
  then H1 "\/" H2 is Subgroup of H by A1,Def4;
  hence thesis by A1,A6,GROUP_2:55;
end;
