reserve x,y for set,
  k,n for Nat,
  i for Integer,
  G for Group,
  a,b,c ,d,e for Element of G,
  A,B,C,D for Subset of G,
  H,H1,H2,H3,H4 for Subgroup of G ,
  N1,N2 for normal Subgroup of G,
  F,F1,F2 for FinSequence of the carrier of G,
  I,I1,I2 for FinSequence of INT;

theorem Th51:
  G is commutative Group iff for A,B st A <> {} & B <> {} holds
  commutators(A,B) = {1_G}
proof
  thus G is commutative Group implies for A,B st A <> {} & B <> {} holds
  commutators(A,B) = {1_G}
  proof
    assume
A1: G is commutative Group;
    let A,B;
    assume
A2: A <> {} & B <> {};
    thus commutators(A,B) c= {1_G}
    proof
      let x be object;
      assume x in commutators(A,B);
      then consider a,b such that
A3:   x = [.a,b.] and
      a in A and
      b in B;
      x = a" * (b" * a) * b by A3,Th16
        .= a" * (a * b") * b by A1,Lm1
        .= b" * b by GROUP_3:1
        .= 1_G by GROUP_1:def 5;
      hence thesis by TARSKI:def 1;
    end;
    set b = the Element of B;
    set a = the Element of A;
    reconsider a,b as Element of G by A2,TARSKI:def 3;
    let x be object;
    assume x in {1_G};
    then
A4: x = 1_G by TARSKI:def 1;
    [.a,b.] = a" * (b" * a) * b by Th16
      .= a" * (a * b") * b by A1,Lm1
      .= b" * b by GROUP_3:1
      .= x by A4,GROUP_1:def 5;
    hence thesis by A2;
  end;
  assume
A5: for A,B st A <> {} & B <> {} holds commutators(A,B) = {1_G};
  G is commutative
  proof
    let a,b;
    a in {a} & b in {b} by TARSKI:def 1;
    then
A6: [.a,b.] in commutators({a},{b});
    commutators({a},{b}) ={1_G} by A5;
    then [.a,b.] = 1_G by A6,TARSKI:def 1;
    then (a" * b") * (a * b) = 1_G by Th16;
    then (b * a)" * (a * b) = 1_G by GROUP_1:17;
    then a * b = (b * a)"" by GROUP_1:12;
    hence thesis;
  end;
  hence thesis;
end;
