reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;

theorem Th51:
  for H being strict GroupWithOperators of O, h being Homomorphism
  of G,H holds h is onto iff Image h = H
proof
  let H be strict GroupWithOperators of O, h be Homomorphism of G,H;
  thus h is onto implies Image h = H
  proof
    reconsider H9=H as strict StableSubgroup of H by Lm3;
    assume rng h = the carrier of H;
    then the carrier of H9 = the carrier of Image h by Th49;
    hence thesis by Lm4;
  end;
  assume
A1: Image h = H;
  the carrier of H c= rng h
  proof
    let x be object;
    assume x in the carrier of H;
    then x in h .: (the carrier of G) by A1,Def22;
    then ex y being object
st y in dom h & y in the carrier of G & h.y = x by
FUNCT_1:def 6;
    hence thesis by FUNCT_1:def 3;
  end;
  then rng h = the carrier of H by XBOOLE_0:def 10;
  hence thesis;
end;
