 reserve a,x for Real;
 reserve n for Nat;
 reserve A for non empty closed_interval Subset of REAL;
 reserve f,f1 for PartFunc of REAL,REAL;
 reserve Z for open Subset of REAL;

theorem
A c= Z & (for x st x in Z holds f.x=(1/(sin.(tan.x))^2)*(1/(cos.x)^2))
& Z c= dom (cot*tan) & Z = dom f & f|A is continuous
implies integral(f,A)=(-cot*tan).(upper_bound A)-(-cot*tan).(lower_bound A)
proof
   assume
A1:A c= Z & (for x st x in Z holds f.x=(1/(sin.(tan.x))^2)*(1/(cos.x)^2))
   & Z c= dom (cot*tan) & Z = dom f & f|A is continuous;
  then
A2:f is_integrable_on A & f|A is bounded by INTEGRA5:10,11;
A3:Z c= dom (-cot*tan) by A1,VALUED_1:8;
A4:cot*tan is_differentiable_on Z by A1,FDIFF_10:4;
then A5:(-1)(#)(cot*tan) is_differentiable_on Z by A3,FDIFF_1:20;
A6:for x st x in Z holds ((-cot*tan)`|Z).x = (1/(sin.(tan.x))^2)*(1/(cos.x)^2)
  proof
    let x;
    assume
A7:x in Z;
  ((-cot*tan)`|Z).x=((-1)(#)((cot*tan)`|Z)).x by A4,FDIFF_2:19
   .=(-1)*(((cot*tan)`|Z).x) by VALUED_1:6
   .=(-1)*((-1/(sin.(tan.x))^2)*(1/(cos.x)^2)) by A1,A7,FDIFF_10:4
   .=(1/(sin.(tan.x))^2)*(1/(cos.x)^2);
     hence thesis;
   end;
A8:for x being Element of REAL st x in dom ((-cot*tan)`|Z)
holds ((-cot*tan)`|Z).x=f.x
  proof
    let x be Element of REAL;
    assume x in dom ((-cot*tan)`|Z);then
A9:x in Z by A5,FDIFF_1:def 7;then
  ((-cot*tan)`|Z).x =(1/(sin.(tan.x))^2)*(1/(cos.x)^2) by A6
  .= f.x by A1,A9;
   hence thesis;
   end;
  dom ((-cot*tan)`|Z)=dom f by A1,A5,FDIFF_1:def 7;
  then ((-cot*tan)`|Z)= f by A8,PARTFUN1:5;
  hence thesis by A1,A2,A5,INTEGRA5:13;
end;
