reserve n for Nat;

theorem Th51:
  for C be compact connected non vertical non horizontal Subset of
TOP-REAL 2 for n be Nat st n > 0 for k be Nat st 1 <= k &
  k < First_Point(L~Upper_Seq(C,n),W-min L~Cage(C,n),E-max L~Cage(C,n),
  Vertical_Line ((W-bound L~Cage(C,n)+E-bound L~Cage(C,n))/2)).. Upper_Seq(C,n)
  holds (Upper_Seq(C,n)/.k)`1 < (W-bound L~Cage(C,n)+E-bound L~Cage(C,n))/2
proof
  let C be compact connected non vertical non horizontal Subset of TOP-REAL 2;
  let n be Nat;
  assume
A1: n > 0;
  set US = Upper_Seq(C,n);
  set sr = (W-bound L~Cage(C,n)+E-bound L~Cage(C,n))/2;
  set Ebo = E-bound L~Cage(C,n);
  set Wbo = W-bound L~Cage(C,n);
  set Emax = E-max L~Cage(C,n);
  set Wmin = W-min L~Cage(C,n);
  set FiP = First_Point(L~US,Wmin,Emax,Vertical_Line sr);
  defpred P[Nat] means 1 <= $1 & $1 < FiP..US implies (US/.$1)`1 < sr;
A2: Wbo < Ebo by SPRECT_1:31;
  then
A3: Wbo < sr by XREAL_1:226;
A4: sr < Ebo by A2,XREAL_1:226;
A5: for k be non zero Nat st P[k] holds P[k+1]
  proof
    set GC1 = Gauge(C,n)*(Center Gauge(C,n),1);
    let k be non zero Nat;
    assume
A6: 1 <= k & k < FiP..US implies (US/.k)`1 < sr;
    4 <= len Gauge(C,n) by JORDAN8:10;
    then 1 <= len Gauge(C,n) by XXREAL_0:2;
    then
A7: 1 <= width Gauge(C,n) by JORDAN8:def 1;
    then
A8: GC1`1 = (W-bound C + E-bound C)/2 by A1,Th35
      .= sr by Th33;
A9: k >= 1 by NAT_1:14;
A10: US/.len US = Emax by JORDAN1F:7;
A11: FiP in rng US by A1,Th47;
    then
A12: FiP..Upper_Seq(C,n) in dom Upper_Seq(C,n) by FINSEQ_4:20;
    then
A13: 1 <= FiP..US by FINSEQ_3:25;
A14: 1 <= Center Gauge(C,n) by JORDAN1B:11;
A15: US/.1 = Wmin by JORDAN1F:5;
    reconsider kk=k as Nat;
    assume that
A16: 1 <= k+1 and
A17: k+1 < FiP..US;
A18: FiP..US <= len US by A12,FINSEQ_3:25;
    then
A19: k+1 <= len US by A17,XXREAL_0:2;
    US is_sequence_on Gauge(C,n) by Th4;
    then consider i1,j1,i2,j2 be Nat such that
A20: [i1,j1] in Indices Gauge(C,n) and
A21: US/.kk = Gauge(C,n)*(i1,j1) and
A22: [i2,j2] in Indices Gauge(C,n) and
A23: US/.(kk+1) = Gauge(C,n)*(i2,j2) and
A24: i1 = i2 & j1+1 = j2 or i1+1 = i2 & j1 = j2 or i1 = i2+1 & j1 = j2
    or i1 = i2 & j1 = j2+1 by A9,A19,JORDAN8:3;
A25: 1 <= i1 by A20,MATRIX_0:32;
A26: 1 <= j1 & j1 <= width Gauge(C,n) by A20,MATRIX_0:32;
A27: j2 <= width Gauge(C,n) by A22,MATRIX_0:32;
A28: 1 <= i2 & 1 <= j2 by A22,MATRIX_0:32;
A29: i2 <= len Gauge(C,n) by A22,MATRIX_0:32;
A30: i1 <= len Gauge(C,n) by A20,MATRIX_0:32;
A31: Center Gauge(C,n) <= len Gauge(C,n) & i1+1 >= 1 by JORDAN1B:13,NAT_1:11;
    now
      per cases by A24;
      suppose
        i1 = i2 & j1+1 = j2;
        then (US/.k)`1 = Gauge(C,n)*(i2,1)`1 by A21,A25,A30,A26,GOBOARD5:2
          .= (US/.(k+1))`1 by A23,A29,A28,A27,GOBOARD5:2;
        hence thesis by A6,A17,NAT_1:13,14;
      end;
      suppose
A32:    i1+1 = i2 & j1 = j2;
A33:    now
A34:      k+1 >= 1+1 by A9,XREAL_1:7;
          len mid(US,1,FiP..US) = FiP..US-'1+1 by A13,A18,FINSEQ_6:186
            .= FiP..US by A13,XREAL_1:235;
          then
A35:      rng mid(US,1,FiP..US) c= L~mid(US,1,FiP..US) by A17,A34,SPPOL_2:18
,XXREAL_0:2;
A36:      US/.(FiP..US) = FiP by A11,FINSEQ_5:38;
A37:      now
            assume US/.1 in Vertical_Line sr;
            then Wmin`1 = sr by A15,JORDAN6:31;
            hence contradiction by A3,EUCLID:52;
          end;
A38:      Wmin`1 <= sr & sr <= Emax`1 by A3,A4,EUCLID:52;
A39:      Vertical_Line sr is closed & L~US is_an_arc_of Wmin,Emax by A15,A10,
JORDAN6:30,TOPREAL1:25;
          First_Point(L~US,US/.1,US/.len US,Vertical_Line sr) in rng US
          by A1,A15,A10,Th47;
          then
A40:      L~mid(US,1,FiP..US) /\ Vertical_Line sr = {FiP} by A15,A10,A39,A38
,A37,Th50,JORDAN6:49;
A41:      mid(US,1,FiP..US) = US|(FiP..US) & US|Seg(FiP..US) = US|(FiP..
          US) by A13,FINSEQ_1:def 16,FINSEQ_6:116;
          assume (US/.(k+1))`1 = sr;
          then US/.(k+1) in {p where p is Point of TOP-REAL 2 : p`1 = sr};
          then
A42:      US/.(k+1) in Vertical_Line sr by JORDAN6:def 6;
A43:      k+1 in dom US by A16,A19,FINSEQ_3:25;
          k+1 in Seg (FiP..US) by A16,A17,FINSEQ_1:1;
          then US/.(k+1) in rng mid(US,1,FiP..US) by A41,A43,PARTFUN2:18;
          then US/.(k+1) in {FiP} by A42,A35,A40,XBOOLE_0:def 4;
          then US/.(k+1) = FiP by TARSKI:def 1;
          hence contradiction by A17,A12,A43,A36,PARTFUN2:10;
        end;
        i1 < Center Gauge(C,n) by A6,A17,A21,A30,A26,A14,A7,A8,JORDAN1A:18
,NAT_1:13,14;
        then i1+1 <= Center Gauge(C,n) by NAT_1:13;
        then (US/.(k+1))`1 <= sr by A23,A26,A7,A8,A31,A32,JORDAN1A:18;
        hence thesis by A33,XXREAL_0:1;
      end;
      suppose
        i1 = i2+1 & j1 = j2;
        then i2 < i1 by NAT_1:13;
        then (US/.(k+1))`1 <= (US/.k)`1 by A21,A23,A30,A26,A28,A27,JORDAN1A:18;
        hence thesis by A6,A17,NAT_1:13,14,XXREAL_0:2;
      end;
      suppose
        i1 = i2 & j1 = j2+1;
        then (US/.k)`1 = Gauge(C,n)*(i2,1)`1 by A21,A25,A30,A26,GOBOARD5:2
          .= (US/.(k+1))`1 by A23,A29,A28,A27,GOBOARD5:2;
        hence thesis by A6,A17,NAT_1:13,14;
      end;
    end;
    hence thesis;
  end;
A44: P[1]
  proof
    assume that
    1 <= 1 and
    1 < FiP..US;
    US/.1 = Wmin by JORDAN1F:5;
    hence thesis by A3,EUCLID:52;
  end;
A45: for k being non zero Nat holds P[k] from NAT_1:sch 10(A44, A5);
  let k be Nat;
  assume 1 <= k & k < First_Point(L~Upper_Seq(C,n),W-min L~Cage(C,n),E-max L~
  Cage(C,n ), Vertical_Line ((W-bound L~Cage(C,n)+E-bound L~Cage(C,n))/2))..
  Upper_Seq(C,n );
  hence thesis by A45;
end;
