reserve m,k,j,j1,i,i1,i2,n for Nat,
  r,s for Real,
  C for compact non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board,
  p for Point of TOP-REAL 2;

theorem
  n is_sufficiently_large_for C implies n >= 1
proof
A1: 2|^0 = 1 by NEWTON:4;
  assume n is_sufficiently_large_for C;
  then consider j such that
A2: j < width Gauge(C,n) and
A3: cell(Gauge(C,n),X-SpanStart(C,n)-'1,j) c= BDD C;
  assume n < 1;
  then
A4: n = 0 by NAT_1:14;
A5: j > 1
  proof
A6: X-SpanStart(C,n)-'1 <= len Gauge(C,n) by Th50;
    assume
A7: j <= 1;
    per cases by A7,NAT_1:25;
    suppose
A8:   j = 0;
      0 <= width Gauge(C,n);
      then
A9:   cell(Gauge(C,n),X-SpanStart(C,n)-'1,0) is non empty by A6,JORDAN1A:24;
      cell(Gauge(C,n),X-SpanStart(C,n)-'1,0) c= UBD C by A6,JORDAN1A:49;
      hence contradiction by A3,A8,A9,JORDAN2C:24,XBOOLE_1:68;
    end;
    suppose
A10:  j = 1;
      set i1 = X-SpanStart(C,n);
      UBD C is_outside_component_of C by JORDAN2C:68;
      then
A11:  UBD C is_a_component_of C` by JORDAN2C:def 3;
      i1 < len Gauge(C,n) & i1-'1 <= i1 by Th49,NAT_D:44;
      then
A12:  i1-'1 < len Gauge(C,n) by XXREAL_0:2;
      BDD C c= C` by JORDAN2C:25;
      then
A13:  cell(Gauge(C,n),X-SpanStart(C,n)-'1,1) c= C` by A3,A10;
A14:  width Gauge(C,n) <> 0 by MATRIX_0:def 10;
      then
A15:  0 qua Nat+1 <= width Gauge(C,n) by NAT_1:14;
      then
A16:  cell(Gauge(C,n),X-SpanStart(C,n)-'1,1) is non empty by A6,JORDAN1A:24;
      1 <= i1-'1 by Th50;
      then cell(Gauge(C,n),i1-'1,0) /\ cell(Gauge(C,n),i1-'1,0 qua Nat+1) =
LSeg(Gauge(C,n)*(i1-'1,0 qua Nat+1),Gauge(C,n)*(i1-'1+1,0 qua Nat+1)) by A14
,A12,GOBOARD5:26;
      then
A17:  cell(Gauge(C,n),i1-'1,0) meets cell(Gauge(C,n),i1-'1,0 qua Nat +1);
      cell(Gauge(C,n),X-SpanStart(C,n)-'1,0) c= UBD C by A6,JORDAN1A:49;
      then cell(Gauge(C,n),X-SpanStart(C,n)-'1,1) c= UBD C by A15,A12,A17,A11
,A13,GOBOARD9:4,JORDAN1A:25;
      hence contradiction by A3,A10,A16,JORDAN2C:24,XBOOLE_1:68;
    end;
  end;
A18: width Gauge(C,n) = 2|^n + 3 by JORDAN1A:28;
  then
A19: j <= 3+1 by A2,A4,NEWTON:4;
A20: j + 1 < width Gauge(C,n)
  proof
    assume j + 1 >= width Gauge(C,n);
    then
A21: j + 1 > width Gauge(C,n) or j + 1 = width Gauge(C,n) by XXREAL_0:1;
A22: X-SpanStart(C,n)-'1 <= len Gauge(C,n) by Th50;
    per cases by A2,A21,NAT_1:13;
    suppose
A23:  j = width Gauge(C,n);
      cell(Gauge(C,n),X-SpanStart(C,n)-'1,width Gauge(C,n)) is non empty
      & cell( Gauge(C,n),X-SpanStart(C,n)-'1,width Gauge(C,n)) c= UBD C by A22,
JORDAN1A:24,50;
      hence contradiction by A3,A23,JORDAN2C:24,XBOOLE_1:68;
    end;
    suppose
      j + 1 = width Gauge(C,n);
      then
A24:  cell(Gauge(C,n),X-SpanStart(C,n)-'1,width Gauge(C,n)-'1) c= BDD C
      by A3,NAT_D:34;
      BDD C c= C` by JORDAN2C:25;
      then
A25:  cell(Gauge(C,n),X-SpanStart(C,n)-'1,width Gauge(C,n)-'1) c= C` by A24;
      set i1 = X-SpanStart(C,n);
A26:  width Gauge(C,n)-1 < width Gauge(C,n) by XREAL_1:146;
      UBD C is_outside_component_of C by JORDAN2C:68;
      then
A27:  UBD C is_a_component_of C` by JORDAN2C:def 3;
      width Gauge(C,n)-'1 <= width Gauge(C,n) by NAT_D:44;
      then
A28:  cell(Gauge(C,n),X-SpanStart(C,n)-'1,width Gauge(C,n)-'1) is non
      empty by A22,JORDAN1A:24;
A29:  cell(Gauge(C,n),X-SpanStart(C,n)-'1,width Gauge(C,n)) c= UBD C by A22,
JORDAN1A:50;
A30:  1 <= i1-'1 by Th50;
      i1 < len Gauge(C,n) & i1-'1 <= i1 by Th49,NAT_D:44;
      then
A31:  i1-'1 < len Gauge(C,n) by XXREAL_0:2;
A32:  width Gauge(C,n) <> 0 by MATRIX_0:def 10;
      then width Gauge(C,n)-'1+1 = width Gauge(C,n) by NAT_1:14,XREAL_1:235;
      then cell(Gauge(C,n),i1-'1,width Gauge(C,n)) /\ cell(Gauge(C,n),i1-'1,
width Gauge(C,n)-'1) = LSeg(Gauge(C,n)*(i1-'1,width Gauge(C,n)), Gauge(C,n)*(i1
      -'1+1,width Gauge(C,n))) by A31,A26,A30,GOBOARD5:26;
      then
A33:  cell(Gauge(C,n),i1-'1,width Gauge(C,n)) meets cell(Gauge(C,n),i1-'1
      ,width Gauge(C,n)-'1);
      width Gauge(C,n)-'1 < width Gauge(C,n) by A32,A26,NAT_1:14,XREAL_1:233;
      then cell(Gauge(C,n),X-SpanStart(C,n)-'1,width Gauge(C,n)-'1) c= UBD C
      by A29,A31,A33,A27,A25,GOBOARD9:4,JORDAN1A:25;
      hence contradiction by A24,A28,JORDAN2C:24,XBOOLE_1:68;
    end;
  end;
  j = 0 or ... or j = 4 by A19;
  then per cases;
  suppose
    j= 0 or j=1;
    hence thesis by A5;
  end;
  suppose
A34: j=2;
A35: X-SpanStart(C,0) = 1 + 2 by A1,NAT_2:8;
    then X-SpanStart(C,0)-'1 = X-SpanStart(C,0)-1 by NAT_D:39
      .= 2 by A35;
    hence contradiction by A3,A4,A34,JORDAN1B:18;
  end;
  suppose
    j=3 or j=4;
    hence thesis by A18,A20,A1,A4;
  end;
end;
