
theorem Th51:
  for seq be ExtREAL_sequence st seq is convergent_to_-infty holds
  not seq is convergent_to_+infty & not seq is convergent_to_finite_number
proof
  let seq be ExtREAL_sequence;
  assume
A1: seq is convergent_to_-infty;
  hereby
    assume seq is convergent_to_+infty;
    then consider n1 being Nat such that
A2: for m be Nat st n1 <= m holds  1 <= seq.m;
    consider n2 being Nat such that
A3: for m be Nat st n2 <= m holds seq.m <=  -1 by A1;
    reconsider n1,n2 as Element of NAT by ORDINAL1:def 12;
    set m = max(n1,n2);
    seq.m <=  -1 by A3,XXREAL_0:25;
    hence contradiction by A2,XXREAL_0:25;
  end;
  assume seq is convergent_to_finite_number;
  then consider g being Real such that
A4: for p be Real st 0 < p ex n be Nat st for m be Nat st n<=m
  holds |.seq.m- g.| < p;
  reconsider g1 = g as R_eal by XXREAL_0:def 1;
  per cases;
  suppose
A5: g > 0;
    then consider n1 be Nat such that
A6: for m be Nat st n1 <= m holds |.seq.m- g.| < (g) by A4;
A7: now
      let m be Element of NAT;
      assume n1 <= m;
      then |.seq.m- g1.| <  g by A6;
      then -g1 < seq.m -  g by EXTREAL1:21;
      then -g + g < seq.m by XXREAL_3:53;
      hence 0 < seq.m;
    end;
    consider n2 be Nat such that
A8: for m be Nat st n2 <= m holds seq.m <=  -g1 by A1,A5;
    reconsider n1,n2 as Element of NAT by ORDINAL1:def 12;
    set m = max(n1,n2);
    0 < seq.m by A7,XXREAL_0:25;
    hence contradiction by A5,A8,XXREAL_0:25;
  end;
  suppose
A9: g = 0;
    consider n1 be Nat such that
A10: for m be Nat st n1 <= m holds |. seq.m- g .| <  1 by A4;
    consider n2 be Nat such that
A11: for m be Nat st n2 <= m holds seq.m <=  -1 by A1;
    reconsider n1,n2 as Element of NAT by ORDINAL1:def 12;
    reconsider jj=1 as R_eal by XXREAL_0:def 1;
    set m = max(n1,n2);
    |. seq.m- g1 .| <  1 by A10,XXREAL_0:25;
    then - jj < seq.m -  g1 by EXTREAL1:21;
    then - 1 +  g < seq.m by XXREAL_3:53;
    then - 1 < seq.m by A9;
    then (-1) < seq.m;
    hence contradiction by A11,XXREAL_0:25;
  end;
  suppose
A12: g < 0;
    then consider n1 be Nat such that
A13: for m be Nat st n1 <= m holds |.seq.m- g.| <  -g1 by A4;
A14: now
      let m be Element of NAT;
      assume n1 <= m;
      then |.seq.m- g1.| <  -g1 by A13;
      then --g1 < seq.m -  g by EXTREAL1:21;
      then g1 +  g < seq.m by XXREAL_3:53;
      then (g+g) < seq.m;
      hence (2*g) < seq.m;
    end;
    consider n2 be Nat such that
A15: for m be Nat st n2 <= m holds seq.m <= 2*g by A1,A12;
    reconsider n1,n2 as Element of NAT by ORDINAL1:def 12;
    set m = max(n1,n2);
    seq.m <= (2*g) by A15,XXREAL_0:25;
    hence contradiction by A14,XXREAL_0:25;
  end;
end;
