reserve X for non empty set,
  S for SigmaField of X,
  M for sigma_Measure of S,
  E for Element of S,
  F,G for Functional_Sequence of X,ExtREAL,
  I for ExtREAL_sequence,
  f,g for PartFunc of X,ExtREAL,
  seq, seq1, seq2 for ExtREAL_sequence,
  p for ExtReal,
  n,m for Nat,
  x for Element of X,
  z,D for set;

theorem Th51:
  E c= dom(F.0) & F is additive & F is with_the_same_dom & (for n
  be Nat holds F.n is nonnegative & F.n is E-measurable) & (for x be 
Element
of X st x in E holds F#x is summable) implies ex I be ExtREAL_sequence st (for
  n be Nat holds I.n = Integral(M,(F.n)|E)) & I is summable & Integral(M,(lim(
  Partial_Sums F))|E) = Sum I
proof
  assume that
A1: E c= dom(F.0) and
A2: F is additive and
A3: F is with_the_same_dom and
A4: for n be Nat holds F.n is nonnegative & F.n is E-measurable and
A5: for x be Element of X st x in E holds F#x is summable;
  deffunc F(Nat) = (F.$1)|E;
  consider G be Functional_Sequence of X,ExtREAL such that
A6: for n be Nat holds G.n = F(n) from SEQFUNC:sch 1;
  reconsider G as additive with_the_same_dom Functional_Sequence of X,ExtREAL
  by A2,A3,A6,Th18,Th31;
A7: for n be Nat holds G.n is nonnegative & G.n is E-measurable
  proof
    let n be Nat;
    (F.n)|E is nonnegative by A4,MESFUNC5:15;
    hence G.n is nonnegative by A6;
    thus thesis by A1,A3,A4,A6,Th20;
  end;
  dom((F.0)|E) = E by A1,RELAT_1:62;
  then
A8: E = dom(G.0) by A6;
A9: for x be Element of X st x in E holds F#x = G#x
  proof
    let x be Element of X;
    assume
A10: x in E;
    for n9 be object st n9 in NAT holds (F#x).n9 = (G#x).n9
    proof
      let n9 be object;
      assume n9 in NAT;
      then reconsider n = n9 as Nat;
      dom(G.n) = E by A8,MESFUNC8:def 2;
      then x in dom((F.n)|E) by A6,A10;
      then ((F.n)|E).x = (F.n).x by FUNCT_1:47;
      then
A11:  (G.n).x = (F.n).x by A6;
      (F#x).n = (F.n).x by MESFUNC5:def 13;
      hence thesis by A11,MESFUNC5:def 13;
    end;
    hence thesis;
  end;
A12: (lim(Partial_Sums G))|E = (lim(Partial_Sums F))|E
  proof
    set E1 = dom(F.0);
    set PF = Partial_Sums F;
    set PG = Partial_Sums G;
A13: dom(lim PG) = dom(PG.0) by MESFUNC8:def 9;
    dom(PF.0) = E1 by A2,A3,Th29;
    then
A14: E c= dom(lim(PF)) by A1,MESFUNC8:def 9;
A15: for x being Element of X st x in dom(lim PG) holds (lim PG).x = (lim PF).x
    proof
      let x being Element of X;
      set PFx = Partial_Sums(F#x);
      set PGx = Partial_Sums(G#x);
      assume
A16:  x in dom(lim PG);
      then
A17:  x in E by A8,A13,Th29;
      for n be Element of NAT holds (PG#x).n = (PF#x).n
      proof
        let n be Element of NAT;
A18:    PGx.n = (PG#x).n by A8,A17,Th32;
        PFx.n = (PF#x).n by A1,A2,A3,A17,Th32;
        hence thesis by A9,A17,A18;
      end;
      then
A19:  lim(PG#x) = lim(PF#x) by FUNCT_2:63;
      (lim PG).x = lim(PG#x) by A16,MESFUNC8:def 9;
      hence thesis by A14,A17,A19,MESFUNC8:def 9;
    end;
A20: dom(PG.0) = dom(G.0) by Th29;
    then
A21: dom((lim PG)|E) = dom(lim PG) by A8,A13;
A22: dom((lim PF)|E) = E by A14,RELAT_1:62;
    then
A23: dom((lim PG)|E) = dom((lim PF)|E) by A8,A20,A13;
    for x be Element of X st x in dom((lim PG)|E) holds ((lim PG)|E).x =
    ((lim PF)|E).x
    proof
      let x be Element of X;
      assume
A24:  x in dom((lim PG)|E);
      then
A25:  ((lim PF)|E).x = (lim PF).x by A23,FUNCT_1:47;
      (lim PG).x = (lim PF).x by A21,A15,A24;
      hence thesis by A24,A25,FUNCT_1:47;
    end;
    hence thesis by A8,A20,A13,A22,PARTFUN1:5;
  end;
  for x be Element of X st x in E holds G#x is summable by A1,A5,A6,Th21;
  then consider I be ExtREAL_sequence such that
A26: for n be Nat holds I.n = Integral(M,(G.n)|E) and
A27: I is summable and
A28: Integral(M,(lim(Partial_Sums G))|E) = Sum I by A8,A7,Lm4;
  take I;
  now
    let n be Nat;
    ((F.n)|E)|E = (F.n)|E;
    then (G.n)|E = (F.n)|E by A6;
    hence I.n = Integral(M,(F.n)|E) by A26;
  end;
  hence thesis by A27,A28,A12;
end;
