reserve X for set,
        n,m,k for Nat,
        K for Field,
        f for n-element real-valued FinSequence,
        M for Matrix of n,m,F_Real;

theorem Th51:
  for n be non empty Nat holds
  RealFuncAdd Seg n = product(the addF of F_Real,n)
  proof
    let n be non empty Nat;
    set OP1 = RealFuncAdd Seg n;
    set OP2 = product(the addF of F_Real,n);
    A1: Funcs(Seg n,REAL) = REAL n by FINSEQ_2:93;
    for x, y be Element of REAL n
    holds OP1 . (x,y) = OP2 . (x,y)
    proof
      let x, y be Element of REAL n;
      reconsider x0 = x, y0 = y as Element of Funcs(Seg n,REAL)
        by FINSEQ_2:93;
      [x,y] in [:REAL n,REAL n:] by ZFMISC_1:87;
      then
      OP2.(x,y) in REAL n by FUNCT_2:5;
      then
      reconsider h = OP2.(x0,y0) as Element of Funcs(Seg n,REAL)
        by FINSEQ_2:93;

      for i be Element of Seg n
      holds h . i = (x0 . i) + (y0 . i)
      proof
        let i be Element of Seg n;
        A2: OP2 . (x0,y0) = addreal .: (x0,y0) by PRVECT_1:def 1;
        dom h = Seg n by FUNCT_2:def 1;
        hence
        h.i = addreal . (x0.i, y0.i) by FUNCOP_1:22,A2
           .= (x0. i) + (y0 . i) by BINOP_2:def 9;
      end;
      hence thesis by FUNCSDOM:1;
    end;
    hence thesis by BINOP_1:2,A1;
  end;
