reserve A for Tolerance_Space,
  X, Y for Subset of A;
reserve A for Approximation_Space,
  X for Subset of A;
reserve A for finite Tolerance_Space,
  X for Subset of A,
  x for Element of A;
reserve A for finite Approximation_Space,
  X, Y for Subset of A,
  x for Element of A;

theorem Th51:
  X misses Y implies MemberFunc (X \/ Y, A).x =
    MemberFunc (X, A).x + MemberFunc (Y, A).x
proof
  assume
A1: X misses Y;
  card ((X \/ Y) /\ Class (the InternalRel of A, x)) = card ((X /\ Class (
  the InternalRel of A, x)) \/ (Y /\ Class (the InternalRel of A, x))) by
XBOOLE_1:23
    .= card (X /\ Class (the InternalRel of A, x)) + card (Y /\ Class (the
  InternalRel of A, x)) by A1,CARD_2:40,XBOOLE_1:76;
  then
  MemberFunc (X \/ Y, A).x = (card (X /\ Class (the InternalRel of A, x))
  + card (Y /\ Class (the InternalRel of A, x))) / (card Class (the InternalRel
  of A, x)) by Def9
    .= card (X /\ Class (the InternalRel of A, x)) / (card Class (the
  InternalRel of A, x)) + card (Y /\ Class (the InternalRel of A, x)) / (card
  Class (the InternalRel of A, x)) by XCMPLX_1:62
    .= MemberFunc (X, A).x + card (Y /\ Class (the InternalRel of A, x)) / (
  card Class (the InternalRel of A, x)) by Def9
    .= MemberFunc (X, A).x + MemberFunc (Y, A).x by Def9;
  hence thesis;
end;
