reserve Y for non empty set,
  G for Subset of PARTITIONS(Y),
  A,B,C,D,E,F for a_partition of Y;
reserve Y for non empty set,
  G for Subset of PARTITIONS(Y),
  A, B, C, D, E, F, J, M for a_partition of Y,
  x,x1,x2,x3,x4,x5,x6,x7,x8,x9 for set;

theorem
  for G being Subset of PARTITIONS(Y), A,B,C,D,E,F,J being a_partition
of Y, z,u being Element of Y st G is independent & G={A,B,C,D,E,F,J} & A<>B & A
<>C & A<>D & A<>E & A<>F & A<>J & B<>C & B<>D & B<>E & B<>F & B<>J & C<>D & C<>
  E & C<>F & C<>J & D<>E & D<>F & D<>J & E<>F & E<>J & F<>J holds EqClass(u,B
  '/\' C '/\' D '/\' E '/\' F '/\' J) meets EqClass(z,A)
proof
  let G be Subset of PARTITIONS(Y);
  let A,B,C,D,E,F,J be a_partition of Y;
  let z,u be Element of Y;
  assume that
A1: G is independent and
A2: G={A,B,C,D,E,F,J} and
A3: A<>B & A<>C & A<>D & A<>E & A<>F & A<>J & B<>C & B<>D & B<>E & B<>F
& B<> J & C<>D & C<>E & C<>F & C<>J & D<>E & D<>F & D<>J & E<>F & E<>J & F<>J;
  set h = (B .--> EqClass(u,B)) +* (C .--> EqClass(u,C)) +* (D .--> EqClass(u,
D)) +* (E .--> EqClass(u,E)) +* (F .--> EqClass(u,F)) +* (J .--> EqClass(u,J))
  +* (A .--> EqClass(z,A));
A4: h.A = EqClass(z,A) by A3,Th49;
  reconsider GG=EqClass(u,B '/\' C '/\' D '/\' E '/\' F '/\' J) as set;
  reconsider I=EqClass(z,A) as set;
  GG = EqClass(u,B '/\' C '/\' D '/\' E '/\' F) /\ EqClass(u,J) by Th1;
  then GG = EqClass(u,B '/\' C '/\' D '/\' E) /\ EqClass(u,F) /\ EqClass(u,J)
  by Th1;
  then GG = EqClass(u,B '/\' C '/\' D) /\ EqClass(u,E) /\ EqClass(u,F) /\
  EqClass(u,J) by Th1;
  then
  GG = EqClass(u,B '/\' C) /\ EqClass(u,D) /\ EqClass(u,E) /\ EqClass (u,
  F) /\ EqClass(u,J) by Th1;
  then
A5: GG /\ I = ((((EqClass(u,B) /\ EqClass(u,C)) /\ EqClass(u,D)) /\ EqClass
  (u,E)) /\ EqClass(u,F) /\ EqClass(u,J)) /\ EqClass(z,A) by Th1;
A6: h.B = EqClass(u,B) by A3,Th49;
A7: h.F = EqClass(u,F) by A3,Th49;
A8: h.E = EqClass(u,E) by A3,Th49;
A9: h.J = EqClass(u,J) by A3,Th49;
A10: h.D = EqClass(u,D) by A3,Th49;
A11: h.C = EqClass(u,C) by A3,Th49;
A12: rng h = {h.A,h.B,h.C,h.D,h.E,h.F,h.J} by Th51;
  rng h c= bool Y
  proof
    let t be object;
    assume t in rng h;
    then t=h.A or t=h.B or t=h.C or t=h.D or t=h.E or t=h.F or t=h.J by A12,
ENUMSET1:def 5;
    hence thesis by A4,A6,A11,A10,A8,A7,A9;
  end;
  then reconsider FF=rng h as Subset-Family of Y;
A13: dom h = G by A2,Th50;
  then A in dom h by A2,ENUMSET1:def 5;
  then
A14: h.A in rng h by FUNCT_1:def 3;
  then
A15: Intersect FF = meet (rng h) by SETFAM_1:def 9;
  for d being set st d in G holds h.d in d
  proof
    let d be set;
    assume d in G;
    then d=A or d=B or d=C or d=D or d=E or d=F or d=J by A2,ENUMSET1:def 5;
    hence thesis by A4,A6,A11,A10,A8,A7,A9;
  end;
  then (Intersect FF)<>{} by A1,A13,BVFUNC_2:def 5;
  then consider m being object such that
A16: m in Intersect FF by XBOOLE_0:def 1;
  C in dom h by A2,A13,ENUMSET1:def 5;
  then h.C in rng h by FUNCT_1:def 3;
  then
A17: m in EqClass(u,C) by A11,A15,A16,SETFAM_1:def 1;
  B in dom h by A2,A13,ENUMSET1:def 5;
  then h.B in rng h by FUNCT_1:def 3;
  then m in EqClass(u,B) by A6,A15,A16,SETFAM_1:def 1;
  then
A18: m in EqClass(u,B) /\ EqClass(u,C) by A17,XBOOLE_0:def 4;
  D in dom h by A2,A13,ENUMSET1:def 5;
  then h.D in rng h by FUNCT_1:def 3;
  then m in EqClass(u,D) by A10,A15,A16,SETFAM_1:def 1;
  then
A19: m in EqClass(u,B) /\ EqClass(u,C) /\ EqClass(u,D) by A18,XBOOLE_0:def 4;
  E in dom h by A2,A13,ENUMSET1:def 5;
  then h.E in rng h by FUNCT_1:def 3;
  then m in EqClass(u,E) by A8,A15,A16,SETFAM_1:def 1;
  then
A20: m in EqClass(u,B) /\ EqClass(u,C) /\ EqClass(u,D) /\ EqClass(u,E) by A19,
XBOOLE_0:def 4;
  F in dom h by A2,A13,ENUMSET1:def 5;
  then h.F in rng h by FUNCT_1:def 3;
  then m in EqClass(u,F) by A7,A15,A16,SETFAM_1:def 1;
  then
A21: m in EqClass(u,B) /\ EqClass(u,C) /\ EqClass(u,D) /\ EqClass(u,E) /\
  EqClass(u,F) by A20,XBOOLE_0:def 4;
  J in dom h by A2,A13,ENUMSET1:def 5;
  then h.J in rng h by FUNCT_1:def 3;
  then m in EqClass(u,J) by A9,A15,A16,SETFAM_1:def 1;
  then
A22: m in EqClass(u,B) /\ EqClass(u,C) /\ EqClass(u,D) /\ EqClass(u,E) /\
  EqClass(u,F) /\ EqClass(u,J) by A21,XBOOLE_0:def 4;
  m in EqClass(z,A) by A4,A14,A15,A16,SETFAM_1:def 1;
  then
  m in EqClass(u,B '/\' C '/\' D '/\' E '/\' F '/\' J) /\ EqClass(z,A) by A5
,A22,XBOOLE_0:def 4;
  hence thesis by XBOOLE_0:def 7;
end;
