reserve
  X for non empty set,
  FX for Filter of X,
  SFX for Subset-Family of X;

theorem Th25:
  for F be sequence of bool NAT st
  for x be Element of NAT holds F.x = {y where y is Element of NAT:x <= y}
  holds rng F is basis of Frechet_Filter(NAT)
  proof
    let F be sequence of bool NAT;
    assume
A1: for x be Element of NAT holds
    F.x = {y where y is Element of NAT:x <= y};
A2: Frechet_Filter(NAT)=the set of all NAT\A where
    A is finite Subset of NAT by Th24;
    for t be object st t in rng F holds t in Frechet_Filter(NAT)
    proof
      let t be object;
      assume
A3:   t in rng F;
      then consider x0 be object such that
A4:   x0 in dom F & t=F.x0 by FUNCT_1:def 3;
      reconsider x2=x0 as natural number by A4;
      reconsider t1=t as Subset of NAT by A3;
A5:   now
        NAT\t1=NAT\{y where y is Element of NAT:x2<=y} by A1,A4;
        hence NAT\t1 is finite by Th22;
        thus NAT\t1 is Subset of NAT;
      end;
      NAT\(NAT\t1)=t1/\NAT by XBOOLE_1:48;
      then t1=NAT\(NAT\t1) by XBOOLE_1:17,XBOOLE_1:19;
      hence thesis by A2,A5;
    end;
    then rng F c= Frechet_Filter(NAT);
    then reconsider F1=rng F as non empty Subset of Frechet_Filter(NAT);
A7: F1 is filter_basis
    proof
      for f be Element of Frechet_Filter(NAT) holds
      ex b be Element of F1 st b c= f
      proof
        let f be Element of Frechet_Filter(NAT);
        f in the set of all NAT\A where A is finite Subset of NAT by A2;
        then consider A0 be finite Subset of NAT such that
A8:     f=NAT\A0;
        reconsider A1=A0 as natural-membered set;
        consider n0 be natural number such that
A9:     A1 c= Segm n0 by AFINSQ_2:2;
        reconsider n1=n0 as Element of NAT by ORDINAL1:def 12;
A10:    dom F = NAT by FUNCT_2:def 1;
        set b=NAT\Segm n0;
        b is Element of rng F
        proof
          b={y where y is Element of NAT: n0 <= y}
          proof
            hereby
              let x be object;
              assume
A11:          x in b;
              then reconsider x1=x as Element of NAT;
              for n0 be natural number,t be Element of NAT\Segm n0
              holds n0 <= t
              proof
                let n0 be natural number,
                t be Element of NAT\Segm n0;
                Segm n0 c< NAT;
                then NAT\Segm n0 is non empty by XBOOLE_1:105;
                then not t in Segm n0 by XBOOLE_0:def 5;
                hence thesis by NAT_1:44;
              end;
              then n0 <= x1 by A11;
              hence x in {y where y is Element of NAT:n0 <=y};
            end;
            let x be object;
            assume x in {y where y is Element of NAT:n0 <= y};
            then consider y0 be Element of NAT such that
A12:         x=y0 and
A13:         n0 <= y0;
            reconsider x1=x as Element of NAT by A12;
            x1 in NAT & not x1 in Segm n0 by A12,A13,NAT_1:44;
            hence x in b by XBOOLE_0:def 5;
          end;
          then b=F.n1 by A1;
          hence thesis by A10,FUNCT_1:3;
        end;
        hence thesis by A8,A9,XBOOLE_1:34;
      end;
      hence thesis;
    end;
    thus thesis by A7;
  end;
