reserve x,y for set,
  i for Nat;
reserve V for non empty CLSStruct,
  u,v,v1,v2,v3 for VECTOR of V,
  A for Subset of V,
  l, l1, l2 for C_Linear_Combination of A,
  x,y,y1,y2 for set,
  a,b for Complex,
  F for FinSequence of the carrier of V,
  f for Function of the carrier of V, COMPLEX;
reserve K,L,L1,L2,L3 for C_Linear_Combination of V;
reserve e,e1,e2 for Element of C_LinComb V;

theorem Th52:
  for V being ComplexLinearSpace, M be non empty Subset of V holds
  0c * M = {0.V}
proof
  let V be ComplexLinearSpace;
  let M be non empty Subset of V;
  for v being Element of V st v in {0.V} holds v in 0c * M
  proof
    let v be Element of V;
    consider x being object such that
A1: x in M by XBOOLE_0:def 1;
    reconsider x as Element of V by A1;
    assume v in {0.V};
    then v = 0.V by TARSKI:def 1;
    then v = 0c * x by CLVECT_1:1;
    hence thesis by A1;
  end;
  then
A2: {0.V} c= 0c * M;
  for v being Element of V st v in 0c * M holds v in {0.V}
  proof
    let v be Element of V;
    assume v in 0c * M;
    then ex x be Element of V st v = 0c * x & x in M;
    then v = 0.V by CLVECT_1:1;
    hence thesis by TARSKI:def 1;
  end;
  then 0c * M c= {0.V};
  hence thesis by A2,XBOOLE_0:def 10;
end;
