
theorem Th52: :: Maxsc:
for R being with_finite_stability# non empty antisymmetric transitive RelStr
 ex S being non empty Subset of R
  st S is strong-chain &
          not ex D being Subset of R st D is strong-chain & S c< D
proof
 let R be with_finite_stability# non empty antisymmetric transitive RelStr;
 set E = { C where C is Subset of R: C is strong-chain };
   set x = the Element of R;
   A1: {x} in E;
   now  :: premise of maximal principle
     let Z be set such that
  A2: Z c= E and
  A3: Z is c=-linear;
     set Y = union Z;
   take Y;
    now
      let B be set;
      assume B in Z;
      then B in E by A2;
      then ex C being Subset of R st C = B & C is strong-chain;
      hence B c= the carrier of R;
    end;
   then reconsider Y9 = Y as Subset of R by ZFMISC_1:76;
   Y9 is strong-chain proof
    let S be finite non empty Subset of R;
     set F = S /\ Y;
    per cases;
    suppose A4: F is empty;
     consider p being Clique-partition of subrelstr S such that
    A5: card p = stability# subrelstr S by Th51;
     take p;
     thus card p <= stability# R by Th44,A5;
     set c = the Element of p;
     take c;
     thus c in p;
     thus S /\ Y9 c= c by A4;
     let d be set such that
    A6: d in p and d <> c;
        d c= the carrier of subrelstr S by A6;
        then d c= S by YELLOW_0:def 15;
     hence Y9 /\ d = {} by A4,XBOOLE_1:3,26;
    end;
    suppose A7: F is non empty;
    then A8: Z is non empty by ZFMISC_1:2;
    defpred P[object,object] means
     ex D2 being set st D2 = $2 & $1 in F & $2 in Z & $1 in D2;
A9: for x being object st x in F ex y being object st y in Z & P[x,y] proof
     let x be object;
     assume A10: x in F;
     then x in Y by XBOOLE_0:def 4;
     then consider y being set such that
     A11: x in y and
     A12: y in Z by TARSKI:def 4;
     take y;
     thus thesis by A12,A10,A11;
   end;
       consider f being Function of F, Z such that
   A13: for x being object st x in F holds P[x,f.x] from FUNCT_2:sch 1(A9);
      set rf = rng f;
 rf c= Z & Z is c=-linear implies rf is c=-linear;
      then consider m being set such that
    A14: m in rf and
    A15: for C being set st C in rf holds C c= m
          by A3,A7,A8,FINSET_1:12,RELAT_1:def 19;
        rf c= Z by RELAT_1:def 19;
        then m in Z by A14;
        then m in E by A2;
        then consider C being Subset of R such that
    A16: m = C and
    A17: C is strong-chain;
    A18: F c= C proof
           let x be object;
           assume A19: x in F;
            then P[x,f.x] by A13;
            then A20: x in f.x;
            f.x c= C by A16,A15,A19,A8,FUNCT_2:4;
           hence x in C by A20;
         end;
        consider p being Clique-partition of subrelstr S such that
    A21: card p <= stability# R and
    A22: ex c being set st c in p & S /\ C c= c &
            for d being set st d in p & d <> c holds C /\ d = {} by A17;
        take p;
        thus card p <= stability# R by A21;
        consider c being set such that
    A23: c in p and
    A24: S /\ C c= c and
    A25: for d being set st d in p & d <> c holds C /\ d = {} by A22;
        take c;
        thus c in p by A23;
        thus S /\ Y9 c= c proof
          let x be object;
          assume x in S /\ Y9;
          then x in S & x in C by A18,XBOOLE_0:def 4;
          then x in S /\ C by XBOOLE_0:def 4;
          hence x in c by A24;
        end;
        let d be set such that
     A26: d in p and
     A27: d <> c;
        assume Y9 /\ d <> {};
        then consider x being object such that
     A28: x in Y9 /\ d by XBOOLE_0:def 1;
     A29: x in Y9 by A28,XBOOLE_0:def 4;
     A30: x in d by A28,XBOOLE_0:def 4;
         d is Subset of S by A26,YELLOW_0:def 15;
         then x in F by A30,A29,XBOOLE_0:def 4;
         then x in C /\ d by A30,A18,XBOOLE_0:def 4;
      hence contradiction by A26,A27,A25;
    end;
   end;
   hence Y in E;
   let X1 be set such that
  A31: X1 in Z;
   thus X1 c= Y by A31,ZFMISC_1:74;
   end;
   then consider Y being set such that
A32: Y in E and
A33: for Z being set st Z in E & Z <> Y holds not Y c= Z by A1,ORDERS_1:65;
   consider C being Subset of R such that
A34: Y = C and
A35: C is strong-chain by A32;
   reconsider S = C as non empty Subset of R by A34,A1,A33,XBOOLE_1:2;
 take S;
 thus S is strong-chain by A35;
 let D be Subset of R such that
A36: D is strong-chain and
A37: S c< D;
A38: D in E by A36;
   D <> S & S c= D by A37;
  hence contradiction by A34,A38,A33;
end;
